1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
|
{
lib,
stdenv,
fetchFromGitHub,
fetchpatch,
pkg-config,
libuuid,
libsodium,
keyutils,
liburcu,
zlib,
libaio,
zstd,
lz4,
attr,
udev,
nixosTests,
fuse3,
cargo,
rustc,
rustPlatform,
makeWrapper,
writeScript,
python3,
fuseSupport ? false,
}:
stdenv.mkDerivation (finalAttrs: {
pname = "bcachefs-tools";
version = "1.7.0";
src = fetchFromGitHub {
owner = "koverstreet";
repo = "bcachefs-tools";
rev = "v${finalAttrs.version}";
hash = "sha256-nHT18bADESDBHoo9P+J3gGc092hRYs2vaWupgqlkvaA=";
};
nativeBuildInputs = [
pkg-config
cargo
rustc
rustPlatform.cargoSetupHook
rustPlatform.bindgenHook
makeWrapper
];
buildInputs = [
libaio
keyutils
lz4
libsodium
liburcu
libuuid
zstd
zlib
attr
udev
] ++ lib.optional fuseSupport fuse3;
cargoDeps = rustPlatform.fetchCargoTarball {
src = finalAttrs.src;
hash = "sha256-RsRz/nb8L+pL1U4l6RnvqeDFddPvcBFH4wdV7G60pxA=";
};
makeFlags = [
"PREFIX=${placeholder "out"}"
"VERSION=${finalAttrs.version}"
"INITRAMFS_DIR=${placeholder "out"}/etc/initramfs-tools"
] ++ lib.optional fuseSupport "BCACHEFS_FUSE=1";
# FIXME: Try enabling this once the default linux kernel is at least 6.7
doCheck = false; # needs bcachefs module loaded on builder
patches = [
# code refactoring of bcachefs-tools broke reading passphrases from stdin (vs. terminal)
# upstream issue https://github.com/koverstreet/bcachefs-tools/issues/261
(fetchpatch {
url = "https://github.com/koverstreet/bcachefs-tools/commit/38b0cb721d2a35f5a4af429bc7bd367461f2fa26.patch";
hash = "sha256-/9reye+Qoa+EMkS+wfdX+KwDeLHHJ/S+Qm7sWl0MtqM=";
})
];
preCheck = lib.optionalString (!fuseSupport) ''
rm tests/test_fuse.py
'';
checkFlags = [ "BCACHEFS_TEST_USE_VALGRIND=no" ];
# Tries to install to the 'systemd-minimal' and 'udev' nix installation paths
installFlags = [
"PKGCONFIG_SERVICEDIR=$(out)/lib/systemd/system"
"PKGCONFIG_UDEVDIR=$(out)/lib/udev"
];
postInstall = ''
substituteInPlace $out/libexec/bcachefsck_all \
--replace "/usr/bin/python3" "${python3}/bin/python3"
'';
passthru = {
tests = {
smoke-test = nixosTests.bcachefs;
inherit (nixosTests.installer) bcachefsSimple bcachefsEncrypted bcachefsMulti;
};
updateScript = writeScript "update-bcachefs-tools-and-cargo-lock.sh" ''
#!/usr/bin/env nix-shell
#!nix-shell -i bash -p curl jq common-updater-scripts
res="$(curl ''${GITHUB_TOKEN:+-u ":$GITHUB_TOKEN"} \
-sL "https://api.github.com/repos/${finalAttrs.src.owner}/${finalAttrs.src.repo}/tags?per_page=1")"
version="$(echo $res | jq '.[0].name | split("v") | .[1]' --raw-output)"
update-source-version ${finalAttrs.pname} "$version" --ignore-same-hash
'';
};
enableParallelBuilding = true;
meta = {
description = "Tool for managing bcachefs filesystems";
homepage = "https://bcachefs.org/";
license = lib.licenses.gpl2Only;
maintainers = with lib.maintainers; [
davidak
johnrtitor
Madouura
];
platforms = lib.platforms.linux;
};
})
|
