1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
|
{ lib, stdenv, fetchFromGitHub, bzip2, zlib, autoconf, automake, cmake, help2man, texinfo, libtool, cppzmq
, libarchive, avro-cpp_llvm, boost, zeromq, openssl, pam, libiodbc, libkrb5, gcc, libcxx, which, catch2
, nanodbc_llvm, fmt, nlohmann_json, spdlog, curl }:
let
avro-cpp = avro-cpp_llvm;
nanodbc = nanodbc_llvm;
in
let
common = import ./common.nix {
inherit lib stdenv bzip2 zlib autoconf automake cmake
help2man texinfo libtool cppzmq libarchive
zeromq openssl pam libiodbc libkrb5 gcc libcxx
boost avro-cpp which catch2 nanodbc fmt nlohmann_json
spdlog curl;
};
in
rec {
# irods: libs and server package
irods = stdenv.mkDerivation (finalAttrs: common // {
version = "4.3.1";
pname = "irods";
src = fetchFromGitHub {
owner = "irods";
repo = "irods";
rev = finalAttrs.version;
sha256 = "sha256-gWgNY8+zD2lRCV5ydOTF0qAgZ1dlQSQKxtdw+U235vg=";
fetchSubmodules = true;
};
# fix build with recent llvm versions
env.NIX_CFLAGS_COMPILE = "-Wno-deprecated-register -Wno-deprecated-declarations";
postPatch = common.postPatch + ''
patchShebangs ./test
substituteInPlace plugins/database/CMakeLists.txt --replace-fail "COMMAND cpp" "COMMAND ${gcc.cc}/bin/cpp"
for file in unit_tests/cmake/test_config/*.cmake
do
substituteInPlace $file --replace-quiet "CATCH2}/include" "CATCH2}/include/catch2"
done
export cmakeFlags="$cmakeFlags
-DCMAKE_EXE_LINKER_FLAGS=-Wl,-rpath,$out/lib
-DCMAKE_MODULE_LINKER_FLAGS=-Wl,-rpath,$out/lib
-DCMAKE_SHARED_LINKER_FLAGS=-Wl,-rpath,$out/lib
"
substituteInPlace server/auth/CMakeLists.txt --replace-fail SETUID ""
'';
meta = common.meta // {
longDescription = common.meta.longDescription + "This package provides the servers and libraries.";
};
});
# icommands (CLI) package, depends on the irods package
irods-icommands = stdenv.mkDerivation (finalAttrs: common // {
version = "4.3.1";
pname = "irods-icommands";
src = fetchFromGitHub {
owner = "irods";
repo = "irods_client_icommands";
rev = finalAttrs.version;
sha256 = "sha256-BjBg13KrCGRLOtGnp23qXOLudLctvu2gJ7wxHFjM5Ug=";
};
buildInputs = common.buildInputs ++ [ irods ];
postPatch = common.postPatch + ''
patchShebangs ./bin
'';
cmakeFlags = common.cmakeFlags ++ [
"-DCMAKE_INSTALL_PREFIX=${stdenv.out}"
"-DIRODS_DIR=${irods}/lib/irods/cmake"
"-DCMAKE_EXE_LINKER_FLAGS=-Wl,-rpath,${irods}/lib"
"-DCMAKE_MODULE_LINKER_FLAGS=-Wl,-rpath,${irods}/lib"
"-DCMAKE_SHARED_LINKER_FLAGS=-Wl,-rpath,${irods}/lib"
];
meta = common.meta // {
description = common.meta.description + " CLI clients";
longDescription = common.meta.longDescription + "This package provides the CLI clients, called 'icommands'.";
};
});
}
|
