blob: 1e161b805e9489774f91009920dc24bdef53175b (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
|
{
lib,
buildGoModule,
fetchFromGitHub,
installShellFiles,
distrobox,
podman,
}:
buildGoModule rec {
pname = "apx";
version = "2.4.2";
src = fetchFromGitHub {
owner = "Vanilla-OS";
repo = "apx";
rev = "v${version}";
hash = "sha256-X6nphUzJc/R3Egw09eRQbza1QebpLGsMIfV7BpLOXTc=";
};
vendorHash = "sha256-hGi+M5RRUL2oyxFGVeR0sum93/CA+FGYy0m4vDmlXTc=";
# podman needed for apx to not error when building shell completions
nativeBuildInputs = [ installShellFiles podman ];
ldflags = [ "-s" "-w" ];
postPatch = ''
substituteInPlace config/apx.json \
--replace-fail "/usr/share/apx/distrobox/distrobox" "${distrobox}/bin/distrobox" \
--replace-fail "/usr/share/apx" "$out/bin/apx"
substituteInPlace settings/config.go \
--replace-fail "/usr/share/apx/" "$out/share/apx/"
'';
postInstall = ''
install -Dm444 config/apx.json -t $out/share/apx/
installManPage man/man1/*
install -Dm444 README.md -t $out/share/docs/apx
install -Dm444 COPYING.md $out/share/licenses/apx/LICENSE
# Create a temp writable home-dir so apx outputs completions without error
export HOME=$(mktemp -d)
# apx command now works (for completions)
# though complains "Error: no such file or directory"
installShellCompletion --cmd apx \
--bash <($out/bin/apx completion bash) \
--fish <($out/bin/apx completion fish) \
--zsh <($out/bin/apx completion zsh)
'';
meta = with lib; {
description = "Vanilla OS package manager";
homepage = "https://github.com/Vanilla-OS/apx";
changelog = "https://github.com/Vanilla-OS/apx/releases/tag/v${version}";
license = licenses.gpl3Only;
maintainers = with maintainers; [ dit7ya chewblacka ];
mainProgram = "apx";
};
}
|
