blob: 2d252819dc02a14967010dc9e089f70bc612f937 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
|
{ lib
, python3
, fetchFromGitHub
, fetchPypi
, nix-update-script
, runtimeShell
, installShellFiles
, testers
, pdm
}:
let
python = python3.override {
# override resolvelib due to
# 1. pdm requiring a later version of resolvelib
# 2. Ansible being packaged as a library
# 3. Ansible being unable to upgrade to a later version of resolvelib
# see here for more details: https://github.com/NixOS/nixpkgs/pull/155380/files#r786255738
packageOverrides = self: super: {
resolvelib = super.resolvelib.overridePythonAttrs rec {
version = "1.0.1";
src = fetchFromGitHub {
owner = "sarugaku";
repo = "resolvelib";
rev = "/refs/tags/${version}";
hash = "sha256-oxyPn3aFPOyx/2aP7Eg2ThtPbyzrFT1JzWqy6GqNbzM=";
};
};
};
self = python;
};
in
with python.pkgs;
buildPythonApplication rec {
pname = "pdm";
version = "2.13.2";
pyproject = true;
disabled = pythonOlder "3.8";
src = fetchPypi {
inherit pname version;
hash = "sha256-4oK/HK8KCD/A+16JrW9518V5/1LHu1juhYfqPVu54Uo=";
};
nativeBuildInputs = [
installShellFiles
];
build-system = [
pdm-backend
];
dependencies = [
blinker
dep-logic
filelock
findpython
hishel
httpx
installer
msgpack
packaging
pbs-installer
platformdirs
pyproject-hooks
python-dotenv
resolvelib
rich
shellingham
tomlkit
unearth
virtualenv
] ++ httpx.optional-dependencies.socks
++ pbs-installer.optional-dependencies.install
++ lib.optionals (pythonOlder "3.11") [
tomli
]
++ lib.optionals (pythonOlder "3.10") [
importlib-metadata
]
++ lib.optionals (pythonAtLeast "3.10") [
truststore
];
makeWrapperArgs = [
"--set PDM_CHECK_UPDATE 0"
];
preInstall = ''
# Silence network warning during pypaInstallPhase
# by disabling latest version check
export PDM_CHECK_UPDATE=0
'';
postInstall = ''
export PDM_LOG_DIR=/tmp/pdm/log
$out/bin/pdm completion bash >pdm.bash
$out/bin/pdm completion fish >pdm.fish
$out/bin/pdm completion zsh >pdm.zsh
installShellCompletion pdm.{bash,fish,zsh}
unset PDM_LOG_DIR
'';
nativeCheckInputs = [
pytestCheckHook
pytest-mock
pytest-xdist
pytest-httpserver
] ++ lib.optional stdenv.isLinux first;
pytestFlagsArray = [
"-m 'not network'"
];
preCheck = ''
export HOME=$TMPDIR
substituteInPlace tests/cli/test_run.py \
--replace-warn "/bin/bash" "${runtimeShell}"
'';
disabledTests = [
# fails to locate setuptools (maybe upstream bug)
"test_convert_setup_py_project"
# pythonfinder isn't aware of nix's python infrastructure
"test_use_wrapper_python"
# touches the network
"test_find_candidates_from_find_links"
];
__darwinAllowLocalNetworking = true;
passthru.tests.version = testers.testVersion {
package = pdm;
};
passthru.updateScript = nix-update-script { };
meta = with lib; {
homepage = "https://pdm-project.org";
changelog = "https://github.com/pdm-project/pdm/releases/tag/${version}";
description = "A modern Python package and dependency manager supporting the latest PEP standards";
license = licenses.mit;
maintainers = with maintainers; [ cpcloud ];
mainProgram = "pdm";
};
}
|
