blob: 68b794214f6ee01fe53c6d3505eaa72eeff83fc1 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
|
{ lib
, stdenv
, makeWrapper
, buildGoModule
, fetchFromGitHub
, installShellFiles
, git
, gnupg
, xclip
, wl-clipboard
, passAlias ? false
}:
buildGoModule rec {
pname = "gopass";
version = "1.15.14";
nativeBuildInputs = [ installShellFiles makeWrapper ];
src = fetchFromGitHub {
owner = "gopasspw";
repo = "gopass";
rev = "v${version}";
hash = "sha256-3oXdHjW3svGfOEoikEeGm4oU9j+7IBOHw5KH7CCV/uw=";
};
vendorHash = "sha256-GeppWyIWE8kYIqhRf1iHksWksdjbIzy96rRpx+qQ3L0=";
subPackages = [ "." ];
ldflags = [ "-s" "-w" "-X main.version=${version}" "-X main.commit=${src.rev}" ];
wrapperPath = lib.makeBinPath (
[
git
gnupg
xclip
] ++ lib.optional stdenv.hostPlatform.isLinux wl-clipboard
);
postInstall = ''
installManPage gopass.1
installShellCompletion --cmd gopass \
--zsh zsh.completion \
--bash bash.completion \
--fish fish.completion
'' + lib.optionalString passAlias ''
ln -s $out/bin/gopass $out/bin/pass
'';
postFixup = ''
wrapProgram $out/bin/gopass \
--prefix PATH : "${wrapperPath}" \
--set GOPASS_NO_REMINDER true
'';
passthru = {
inherit wrapperPath;
};
meta = with lib; {
description = "Slightly more awesome Standard Unix Password Manager for Teams. Written in Go";
homepage = "https://www.gopass.pw/";
license = licenses.mit;
maintainers = with maintainers; [ rvolosatovs sikmir ];
changelog = "https://github.com/gopasspw/gopass/blob/v${version}/CHANGELOG.md";
longDescription = ''
gopass is a rewrite of the pass password manager in Go with the aim of
making it cross-platform and adding additional features. Our target
audience are professional developers and sysadmins (and especially teams
of those) who are well versed with a command line interface. One explicit
goal for this project is to make it more approachable to non-technical
users. We go by the UNIX philosophy and try to do one thing and do it
well, providing a stellar user experience and a sane, simple interface.
'';
mainProgram = "gopass";
};
}
|
