blob: 4cc831eda391a53fff9db54d826575bedaf43efd (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
|
{ lib, stdenv, fetchFromGitHub, pkgconfig, ncurses, readline, pcsclite, qt5
, gcc-arm-embedded }:
let
generic = { pname, version, rev, sha256 }:
stdenv.mkDerivation rec {
inherit pname version;
src = fetchFromGitHub {
owner = "Proxmark";
repo = "proxmark3";
inherit rev sha256;
};
nativeBuildInputs = [ pkgconfig gcc-arm-embedded ];
buildInputs = [ ncurses readline pcsclite qt5.qtbase ];
postPatch = ''
substituteInPlace client/Makefile --replace '-ltermcap' ' '
substituteInPlace liblua/Makefile --replace '-ltermcap' ' '
substituteInPlace client/flasher.c \
--replace 'armsrc/obj/fullimage.elf' \
'${placeholder "out"}/firmware/fullimage.elf'
'';
buildPhase = ''
make bootrom/obj/bootrom.elf armsrc/obj/fullimage.elf client
'';
installPhase = ''
install -Dt $out/bin client/proxmark3
install -T client/flasher $out/bin/proxmark3-flasher
install -Dt $out/firmware bootrom/obj/bootrom.elf armsrc/obj/fullimage.elf
'';
meta = with lib; {
description = "Client for proxmark3, powerful general purpose RFID tool";
homepage = "http://www.proxmark.org";
license = licenses.gpl2Plus;
maintainers = with maintainers; [ fpletz ];
};
};
in
{
proxmark3 = generic rec {
pname = "proxmark3";
version = "3.1.0";
rev = "v${version}";
sha256 = "1qw28n1bhhl91ix77lv50qcr919fq3hjc8zhhqphwxal2svgx2jf";
};
proxmark3-unstable = generic {
pname = "proxmark3-unstable";
version = "2019-12-28";
rev = "a4ff62be63ca2a81071e9aa2b882bd3ff57f13ad";
sha256 = "067lp28xqx61n3i2a2fy489r5frwxqrcfj8cpv3xdzi3gb3vk5c3";
};
}
|