1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
|
{ lib
, stdenv
, rustPlatform
, fetchzip
, openssl
, pkg-config
, installShellFiles
, darwin
, bash
# rbw-fzf
, withFzf ? false
, fzf
, perl
# rbw-rofi
, withRofi ? false
, rofi
, xclip
# pass-import
, withPass ? false
, pass
}:
rustPlatform.buildRustPackage rec {
pname = "rbw";
version = "1.10.0";
src = fetchzip {
url = "https://git.tozt.net/rbw/snapshot/rbw-${version}.tar.gz";
hash = "sha256-uJ1QLEaab/Vb5GiAmbwjve3Y/3SM2XbNTRTvl2vPDYc=";
};
cargoHash = "sha256-tDgkANbUmNLe3us+05gD9IS0f+RTQBXTGvuz2cr2zYY=";
nativeBuildInputs = [
installShellFiles
] ++ lib.optionals stdenv.isLinux [ pkg-config ];
buildInputs = [ bash ] # for git-credential-rbw
++ lib.optionals stdenv.isDarwin [
darwin.apple_sdk_11_0.frameworks.Security
darwin.apple_sdk_11_0.frameworks.AppKit
];
preConfigure = lib.optionalString stdenv.isLinux ''
export OPENSSL_INCLUDE_DIR="${openssl.dev}/include"
export OPENSSL_LIB_DIR="${lib.getLib openssl}/lib"
'';
postInstall = ''
install -Dm755 -t $out/bin bin/git-credential-rbw
installShellCompletion --cmd rbw \
--bash <($out/bin/rbw gen-completions bash) \
--fish <($out/bin/rbw gen-completions fish) \
--zsh <($out/bin/rbw gen-completions zsh)
'' + lib.optionalString withFzf ''
install -Dm755 -t $out/bin bin/rbw-fzf
substituteInPlace $out/bin/rbw-fzf \
--replace fzf ${fzf}/bin/fzf \
--replace perl ${perl}/bin/perl
'' + lib.optionalString withRofi ''
install -Dm755 -t $out/bin bin/rbw-rofi
substituteInPlace $out/bin/rbw-rofi \
--replace rofi ${rofi}/bin/rofi \
--replace xclip ${xclip}/bin/xclip
'' + lib.optionalString withPass ''
install -Dm755 -t $out/bin bin/pass-import
substituteInPlace $out/bin/pass-import \
--replace pass ${pass}/bin/pass
'';
meta = with lib; {
description = "Unofficial command line client for Bitwarden";
homepage = "https://crates.io/crates/rbw";
changelog = "https://git.tozt.net/rbw/plain/CHANGELOG.md?id=${version}";
license = licenses.mit;
maintainers = with maintainers; [ albakham luc65r ];
};
}
|
