blob: 56c227b46da451850c0ed28d564d8ab247a33979 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
|
{ fetchFromGitHub
, git
, jdk_headless
, jre_headless
, makeWrapper
, python3
, stdenvNoCC
, lib
, testers
}:
let
pname = "validator-nu";
version = "23.4.11-unstable-2023-12-18";
src = fetchFromGitHub {
owner = "validator";
repo = "validator";
rev = "c3a401feb6555affdc891337f5a40af238f9ac2d";
fetchSubmodules = true;
hash = "sha256-pcA3HXduzFKzoOHhor12qvzbGSSvo3k3Bpy2MvvQlCI=";
};
deps = stdenvNoCC.mkDerivation {
pname = "${pname}-deps";
inherit version src;
nativeBuildInputs = [ git jdk_headless python3 python3.pkgs.certifi ];
buildPhase = ''
python checker.py dldeps
'';
installPhase = ''
mkdir "$out"
mv dependencies extras "$out"
'';
outputHashMode = "recursive";
outputHash = "sha256-LPtxpUd7LAYZHJL7elgcZOTaTgHqeqquiB9hiuajA6c=";
};
in
stdenvNoCC.mkDerivation (finalAttrs: {
inherit pname version src;
nativeBuildInputs = [ git jdk_headless makeWrapper python3 ];
postPatch = ''
substituteInPlace build/build.py --replace-warn \
'validatorVersion = "%s.%s.%s" % (year, month, day)' \
'validatorVersion = "${finalAttrs.version}"'
'';
buildPhase = ''
ln -s '${deps}/dependencies' '${deps}/extras' .
JAVA_HOME='${jdk_headless}' python checker.py build
'';
installPhase = ''
runHook preInstall
mkdir -p "$out/bin" "$out/share/java"
mv build/dist/vnu.jar "$out/share/java/"
makeWrapper "${jre_headless}/bin/java" "$out/bin/vnu" \
--add-flags "-jar '$out/share/java/vnu.jar'"
runHook postInstall
'';
passthru.tests.version = testers.testVersion {
package = finalAttrs.finalPackage;
};
meta = {
description = "Helps you catch problems in your HTML/CSS/SVG";
homepage = "https://validator.github.io/validator/";
license = lib.licenses.mit;
maintainers = with lib.maintainers; [ andersk ivan ];
mainProgram = "vnu";
sourceProvenance = with lib.sourceTypes; [ binaryBytecode fromSource ];
};
})
|
