pkgs/top-level/packages-config.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44

# Used in the generation of package search database.
{
  # Ensures no aliases are in the results.
  allowAliases = false;

  # Enable recursion into attribute sets that nix-env normally doesn't look into
  # so that we can get a more complete picture of the available packages for the
  # purposes of the index.
  packageOverrides = super: with super; lib.mapAttrs (_: set: recurseIntoAttrs set) {
    inherit (super)
      agdaPackages
      apacheHttpdPackages
      fdbPackages
      fusePackages
      gns3Packages
      haskellPackages
      idrisPackages
      nodePackages
      nodePackages_latest
      platformioPackages
      rPackages
      roundcubePlugins
      sourceHanPackages
      steamPackages
      ut2004Packages
      zabbix50
      zabbix60
      zeroadPackages
    ;

    # Make sure haskell.compiler is included, so alternative GHC versions show up,
    # but don't add haskell.packages.* since they contain the same packages (at
    # least by name) as haskellPackages.
    haskell = super.haskell // {
      compiler = recurseIntoAttrs super.haskell.compiler;
    };

    # minimal-bootstrap packages aren't used for anything but bootstrapping our
    # stdenv. They should not be used for any other purpose and therefore not
    # show up in search results or repository tracking services that consume our
    # packages.json https://github.com/NixOS/nixpkgs/issues/244966
    minimal-bootstrap = { };
  };
}