1 files changed, 29 insertions, 0 deletions
diff --git a/pkgs/build-support/channel.nix b/pkgs/build-support/channel.nix
new file mode 100644
index 00000000..ff0fecb3
--- /dev/null
+++ b/pkgs/build-support/channel.nix
@@ -0,0 +1,29 @@
+{ stdenv }:
+
+{ name, channelName ? null, src, constituents ? [], meta ? {}, ... }@args:
+
+stdenv.mkDerivation {
+  inherit name channelName src constituents meta;
+  _hydraAggregate = true;
+
+  phases = [ "unpackPhase" "installPhase" ];
+  installPhase = ''
+    mkdir -p "$out/tarballs" "$out/nix-support"
+
+    tar cJf "$out/tarballs/nixexprs.tar.xz" \
+      --owner=0 --group=0 --mtime="1970-01-01 00:00:00 UTC" \
+      --transform='s!^\.!${name}!' .
+    if [ -z "$channelName" ]; then
+      echo "file channel $out/tarballs/nixexprs.tar.xz"
+    else
+      echo "file channel \"$channelName\" $out/tarballs/nixexprs.tar.xz"
+    fi > "$out/nix-support/hydra-build-products"
+
+    echo $constituents > "$out/nix-support/hydra-aggregate-constituents"
+    for i in $constituents; do
+      if [ -e "$i/nix-support/failed" ]; then
+        touch "$out/nix-support/failed"
+      fi
+    done
+  '';
+} // removeAttrs args [ "name" "channelName" "src" "constituents" "meta" ]