Merge pull request #233304 from figsoda/shell2http

shell2http: init at 1.16.0

2 files changed, 53 insertions, 0 deletions

diff --git a/pkgs/servers/misc/shell2http/default.nix b/pkgs/servers/misc/shell2http/default.nix
new file mode 100644
index 0000000000000..994df898215fd
--- /dev/null
+++ b/pkgs/servers/misc/shell2http/default.nix
@@ -0,0 +1,51 @@
+{ lib
+, buildGoModule
+, fetchFromGitHub
+, installShellFiles
+, testers
+, shell2http
+}:
+
+buildGoModule rec {
+  pname = "shell2http";
+  version = "1.16.0";
+
+  src = fetchFromGitHub {
+    owner = "msoap";
+    repo = "shell2http";
+    rev = "v${version}";
+    hash = "sha256-FHLClAQYCR6DMzHyAo4gjN2nCmMptYevKJbhEZ8AJyE=";
+  };
+
+  vendorHash = "sha256-K/0ictKvX0sl/5hFDKjTkpGMze0x9fJA98RXNsep+DM=";
+
+  nativeBuildInputs = [
+    installShellFiles
+  ];
+
+  ldflags = [
+    "-s"
+    "-w"
+    "-X=main.version=${version}"
+  ];
+
+  postInstall = ''
+    installManPage shell2http.1
+  '';
+
+  passthru.tests = {
+    version = testers.testVersion {
+      package = shell2http;
+    };
+  };
+
+  __darwinAllowLocalNetworking = true;
+
+  meta = with lib; {
+    description = "Executing shell commands via HTTP server";
+    homepage = "https://github.com/msoap/shell2http";
+    changelog = "https://github.com/msoap/shell2http/releases/tag/${src.rev}";
+    license = licenses.mit;
+    maintainers = with maintainers; [ figsoda ];
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 5f848233a4d20..0ee0c60a11d86 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -12253,6 +12253,8 @@ with pkgs;
 
   sharutils = callPackage ../tools/archivers/sharutils { };
 
+  shell2http = callPackage ../servers/misc/shell2http { };
+
   shelldap = callPackage ../tools/misc/shelldap { };
 
   shellspec = callPackage ../tools/misc/shellspec { };