chia-dev-tools: init at 1.1.4

2 files changed, 76 insertions, 0 deletions

diff --git a/pkgs/applications/blockchains/chia-dev-tools/default.nix b/pkgs/applications/blockchains/chia-dev-tools/default.nix
new file mode 100644
index 0000000000000..1b40e6ddb041f
--- /dev/null
+++ b/pkgs/applications/blockchains/chia-dev-tools/default.nix
@@ -0,0 +1,63 @@
+{ lib
+, fetchFromGitHub
+, substituteAll
+, python3Packages
+, chia
+,
+}:
+python3Packages.buildPythonApplication rec {
+  pname = "chia-dev-tools";
+  version = "1.1.4";
+
+  src = fetchFromGitHub {
+    owner = "Chia-Network";
+    repo = pname;
+    rev = "v${version}";
+    hash = "sha256-lE7FTSDqVS6AstcxZSMdQwgygMvcvh1fqYVTTSSNZpA=";
+  };
+
+  patches = [
+    (substituteAll {
+      src = ./fix-paths.patch;
+      inherit chia;
+    })
+  ];
+
+  postPatch = ''
+    substituteInPlace setup.py \
+      --replace "==" ">="
+  '';
+
+  nativeBuildInputs = [
+    python3Packages.setuptools-scm
+  ];
+
+  # give a hint to setuptools-scm on package version
+  SETUPTOOLS_SCM_PRETEND_VERSION = "v${version}";
+
+  propagatedBuildInputs = with python3Packages; [
+    (toPythonModule chia)
+    pytimeparse
+  ];
+
+  checkInputs = with python3Packages; [
+    pytestCheckHook
+    pytest-asyncio
+  ];
+
+  preCheck = ''
+    export HOME=$(mktemp -d)
+  '';
+  postCheck = "unset HOME";
+
+  disabledTests = [
+    "test_spendbundles"
+  ];
+
+  meta = with lib; {
+    homepage = "https://www.chia.net/";
+    description = "Utility for developing in the Chia ecosystem: Chialisp functions, object inspection, RPC client and more";
+    license = with licenses; [ asl20 ];
+    maintainers = teams.chia.members;
+  };
+}
diff --git a/pkgs/applications/blockchains/chia-dev-tools/fix-paths.patch b/pkgs/applications/blockchains/chia-dev-tools/fix-paths.patch
new file mode 100644
index 0000000000000..9fb8fefe197af
--- /dev/null
+++ b/pkgs/applications/blockchains/chia-dev-tools/fix-paths.patch
@@ -0,0 +1,13 @@
+diff --git a/cdv/cmds/sim_utils.py b/cdv/cmds/sim_utils.py
+index e59ba8f..20912ff 100644
+--- a/cdv/cmds/sim_utils.py
++++ b/cdv/cmds/sim_utils.py
+@@ -67,7 +67,7 @@ async def start_async(root_path: Path, group: Any, restart: bool) -> None:
+ 

+     from chia.cmds.start_funcs import async_start

+ 

+-    sys.argv[0] = str(Path(sys.executable).parent / "chia")  # this gives the correct path to the chia executable

++    sys.argv[0] = "@chia@/bin/chia"  # this gives the correct path to the chia executable

+     if root_path.exists():

+         config = load_config(root_path, "config.yaml")

+         await async_start(root_path, config, group, restart)