genesys: init at 1.0.7

1 files changed, 38 insertions, 0 deletions

diff --git a/pkgs/applications/misc/genesys/default.nix b/pkgs/applications/misc/genesys/default.nix
new file mode 100644
index 0000000000000..b7d8c3796dda5
--- /dev/null
+++ b/pkgs/applications/misc/genesys/default.nix
@@ -0,0 +1,38 @@
+{ lib, stdenv, fetchurl, jre, graphviz, makeWrapper }:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "genesys";
+  version = "1.0.7";
+
+  src = fetchurl {
+    url = "https://github.com/mrlem/genesys/releases/download/v${finalAttrs.version}/${finalAttrs.pname}-${finalAttrs.version}.tar.gz";
+    hash = "sha256-I1lEVvwRiGf1f4zUtqKhSb+it/nC8WAmw5S6edquOj8=";
+  };
+
+  nativeBuildInputs = [ makeWrapper ];
+
+  # The package is distributed as a prebuilt JAVA binary
+  dontConfigure = true;
+  dontBuild = true;
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out
+    mv bin lib $out
+    wrapProgram $out/bin/${finalAttrs.pname} \
+      --set JAVA_HOME "${jre.home}" \
+      --prefix PATH : "${graphviz}/bin"
+
+    runHook postInstall
+  '';
+
+  meta = {
+    description = "A simple family tree generator that scales";
+    homepage = "https://github.com/mrlem/genesys";
+    license = lib.licenses.gpl3;
+    maintainers = with lib.maintainers; [ rogarb ];
+    platforms = lib.platforms.all;
+  };
+})
+