Merge pull request #300271 from devhell/bump-mediainfo

{lib}mediainfo{-gui}: 24.01{.1} -> 24.03

1 files changed, 39 insertions, 0 deletions

diff --git a/pkgs/by-name/li/libmediainfo/package.nix b/pkgs/by-name/li/libmediainfo/package.nix
new file mode 100644
index 0000000000000..c0abeb221ec89
--- /dev/null
+++ b/pkgs/by-name/li/libmediainfo/package.nix
@@ -0,0 +1,39 @@
+{ lib, stdenv, fetchurl, autoreconfHook, pkg-config, libzen, zlib }:
+
+stdenv.mkDerivation rec {
+  pname = "libmediainfo";
+  version = "24.03";
+
+  src = fetchurl {
+    url = "https://mediaarea.net/download/source/libmediainfo/${version}/libmediainfo_${version}.tar.xz";
+    hash = "sha256-zCu0TkB8iQq1ZpNMVnY5GFBatYwUE0tT8NHanuokLI0=";
+  };
+
+  nativeBuildInputs = [ autoreconfHook pkg-config ];
+  buildInputs = [ zlib ];
+  propagatedBuildInputs = [ libzen ];
+
+  sourceRoot = "MediaInfoLib/Project/GNU/Library";
+
+  postPatch = lib.optionalString (stdenv.cc.targetPrefix != "") ''
+    substituteInPlace configure.ac \
+      --replace "pkg-config " "${stdenv.cc.targetPrefix}pkg-config "
+  '';
+
+  configureFlags = [ "--enable-shared" ];
+
+  enableParallelBuilding = true;
+
+  postInstall = ''
+    install -vD -m 644 libmediainfo.pc "$out/lib/pkgconfig/libmediainfo.pc"
+  '';
+
+  meta = with lib; {
+    description = "Shared library for mediainfo";
+    homepage = "https://mediaarea.net/";
+    changelog = "https://mediaarea.net/MediaInfo/ChangeLog";
+    license = licenses.bsd2;
+    platforms = platforms.unix;
+    maintainers = [ maintainers.devhell ];
+  };
+}