Merge pull request #312426 from jonochang/jonochang-add-stackql

stackql: init at 0.5.643

1 files changed, 48 insertions, 0 deletions

diff --git a/pkgs/by-name/st/stackql/package.nix b/pkgs/by-name/st/stackql/package.nix
new file mode 100644
index 0000000000000..69c137e12d05e
--- /dev/null
+++ b/pkgs/by-name/st/stackql/package.nix
@@ -0,0 +1,48 @@
+{
+  lib,
+  fetchFromGitHub,
+  buildGoModule,
+  testers,
+  stackql,
+}:
+
+buildGoModule rec {
+  pname = "stackql";
+  version = "0.5.643";
+
+  src = fetchFromGitHub {
+    owner = "stackql";
+    repo = "stackql";
+    rev = "v${version}";
+    hash = "sha256-9W6bEI+5Q0Kgbd14sWKde3I6WIVz1ZxsXmR009mOPog=";
+  };
+
+  vendorHash = "sha256-xcly4jtdUkx/s+YWYFBVeuI2kQBu2oqbLN9ZKkHppkA=";
+
+  ldflags = [
+    "-s"
+    "-w"
+    "-X github.com/stackql/stackql/internal/stackql/cmd.BuildMajorVersion=${builtins.elemAt (lib.splitVersion version) 0}"
+    "-X github.com/stackql/stackql/internal/stackql/cmd.BuildMinorVersion=${builtins.elemAt (lib.splitVersion version) 1}"
+    "-X github.com/stackql/stackql/internal/stackql/cmd.BuildPatchVersion=${builtins.elemAt (lib.splitVersion version) 2}"
+    "-X github.com/stackql/stackql/internal/stackql/cmd.BuildDate=2024-05-15T07:51:52Z" # date of commit hash
+    "-X stackql/internal/stackql/planbuilder.PlanCacheEnabled=true"
+  ];
+
+  __darwinAllowLocalNetworking = true;
+
+  checkFlags = [ "--tags json1,sqleanal" ];
+
+  passthru.tests.version = testers.testVersion {
+    package = stackql;
+    version = "v${version}";
+  };
+
+  meta = {
+    homepage = "https://github.com/stackql/stackql";
+    description = "Deploy, manage and query cloud resources and interact with APIs using SQL";
+    mainProgram = "stackql";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ jonochang ];
+  };
+}