wazero: init at 1.2.1

https://github.com/tetratelabs/wazero

1 files changed, 50 insertions, 0 deletions

diff --git a/pkgs/development/interpreters/wazero/default.nix b/pkgs/development/interpreters/wazero/default.nix
new file mode 100644
index 000000000000..ab43d96db745
--- /dev/null
+++ b/pkgs/development/interpreters/wazero/default.nix
@@ -0,0 +1,50 @@
+{ lib
+, buildGoModule
+, fetchFromGitHub
+, testers
+, wazero
+}:
+
+buildGoModule rec {
+  pname = "wazero";
+  version = "1.2.1";
+
+  src = fetchFromGitHub {
+    owner = "tetratelabs";
+    repo = "wazero";
+    rev = "v${version}";
+    hash = "sha256-u9VsSV+pdyBnAmT910SOL1I8tpDCYAWFTfWkWTNWQVs=";
+  };
+
+  vendorHash = null;
+
+  subPackages = [
+    "cmd/wazero"
+  ];
+
+  ldflags = [
+    "-s"
+    "-w"
+    "-X=github.com/tetratelabs/wazero/internal/version.version=${version}"
+  ];
+
+  checkFlags = [
+    # fails when version is specified
+    "-skip=TestCompile|TestRun"
+  ];
+
+  passthru.tests = {
+    version = testers.testVersion {
+      package = wazero;
+      command = "wazero version";
+    };
+  };
+
+  meta = with lib; {
+    description = "A zero dependency WebAssembly runtime for Go developers";
+    homepage = "https://github.com/tetratelabs/wazero";
+    changelog = "https://github.com/tetratelabs/wazero/releases/tag/${src.rev}";
+    license = licenses.asl20;
+    maintainers = with maintainers; [ figsoda ];
+  };
+}