pythonPackages.filemagic: init at 1.6

1 files changed, 29 insertions, 0 deletions

diff --git a/pkgs/development/python-modules/filemagic/default.nix b/pkgs/development/python-modules/filemagic/default.nix
new file mode 100644
index 0000000000000..731b83294a8fe
--- /dev/null
+++ b/pkgs/development/python-modules/filemagic/default.nix
@@ -0,0 +1,29 @@
+{ stdenv, lib, buildPythonPackage, fetchFromGitHub, file
+, isPy3k, mock, unittest2 }:
+
+buildPythonPackage rec {
+  pname = "filemagic";
+  version = "1.6";
+
+  # Don't use the PyPI source because it's missing files required for testing
+  src = fetchFromGitHub {
+    owner = "aliles";
+    repo = "filemagic";
+    rev = "138649062f769fb10c256e454a3e94ecfbf3017b";
+    sha256 = "1jxf928jjl2v6zv8kdnfqvywdwql1zqkm1v5xn1d5w0qjcg38d4n";
+  };
+
+  postPatch = ''
+    substituteInPlace magic/api.py --replace "ctypes.util.find_library('magic')" \
+      "'${file}/lib/libmagic${stdenv.hostPlatform.extensions.sharedLibrary}'"
+  '';
+
+  checkInputs = [ (if isPy3k then mock else unittest2) ];
+
+  meta = with lib; {
+    description = "File type identification using libmagic";
+    homepage = https://github.com/aliles/filemagic;
+    license = licenses.asl20;
+    maintainers = with maintainers; [ earvstedt ];
+  };
+}