1 files changed, 64 insertions, 0 deletions
diff --git a/pkgs/applications/kde/audiotube.nix b/pkgs/applications/kde/audiotube.nix
new file mode 100644
index 0000000000000..0bd22ee06f63a
--- /dev/null
+++ b/pkgs/applications/kde/audiotube.nix
@@ -0,0 +1,64 @@
+{ lib
+, mkDerivation
+
+, extra-cmake-modules
+, wrapGAppsHook
+
+, gst_all_1
+, kcoreaddons
+, kcrash
+, ki18n
+, kirigami2
+, kirigami-addons
+, qtimageformats
+, qtmultimedia
+, qtquickcontrols2
+, python3Packages
+}:
+
+mkDerivation rec {
+  pname = "audiotube";
+
+  nativeBuildInputs = [
+    extra-cmake-modules
+    wrapGAppsHook
+    python3Packages.wrapPython
+    python3Packages.pybind11
+  ];
+
+  buildInputs = [
+    kcoreaddons
+    kcrash
+    ki18n
+    kirigami2
+    kirigami-addons
+    qtimageformats
+    qtmultimedia
+    qtquickcontrols2
+  ] ++ (with gst_all_1; [
+    gst-plugins-bad
+    gst-plugins-base
+    gst-plugins-good
+    gstreamer
+  ]) ++ pythonPath;
+
+  pythonPath = with python3Packages; [
+    yt-dlp
+    ytmusicapi
+  ];
+
+  preFixup = ''
+    buildPythonPath "$pythonPath"
+    qtWrapperArgs+=(--prefix PYTHONPATH : "$program_PYTHONPATH")
+    qtWrapperArgs+=("''${gappsWrapperArgs[@]}")
+  '';
+  dontWrapGApps = true;
+
+  meta = with lib; {
+    description = "Client for YouTube Music";
+    homepage = "https://invent.kde.org/plasma-mobile/audiotube";
+    # https://invent.kde.org/plasma-mobile/audiotube/-/tree/c503d0607a3386112beaa9cf990ab85fe33ef115/LICENSES
+    license = with licenses; [ bsd2 cc0 gpl2Only gpl3Only ];
+    maintainers = with maintainers; [ samueldr ];
+  };
+}