1 files changed, 49 insertions, 0 deletions
diff --git a/pkgs/by-name/bu/butt/package.nix b/pkgs/by-name/bu/butt/package.nix
new file mode 100644
index 0000000000000..6f2e7729797c7
--- /dev/null
+++ b/pkgs/by-name/bu/butt/package.nix
@@ -0,0 +1,49 @@
+{ lib, stdenv, fetchurl, pkg-config, fltk13, portaudio, lame, libvorbis, libogg
+, flac, libopus, libsamplerate, fdk_aac, dbus, openssl, curl }:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "butt";
+  version = "0.1.40";
+
+  src = fetchurl {
+    url = "https://danielnoethen.de/butt/release/${finalAttrs.version}/butt-${finalAttrs.version}.tar.gz";
+    hash = "sha256-wag177UIQ6YpBkJ5XQlxYtTdBFFNO5q+BLD/CiUkGoA=";
+  };
+
+  postPatch = ''
+    # remove advertising
+    substituteInPlace src/FLTK/flgui.cpp \
+      --replace 'idata_radio_co_badge, 124, 61, 4,' 'nullptr, 0, 0, 0,'
+  '';
+
+  nativeBuildInputs = [ pkg-config ];
+
+  buildInputs = [
+    fltk13
+    portaudio
+    lame
+    libvorbis
+    libogg
+    flac
+    libopus
+    libsamplerate
+    fdk_aac
+    dbus
+    openssl
+    curl
+  ];
+
+  postInstall = ''
+    cp -r usr/share $out/
+  '';
+
+  meta = {
+    changelog = "https://danielnoethen.de/butt/Changelog.html";
+    description =
+      "butt (broadcast using this tool) is an easy to use, multi OS streaming tool";
+    homepage = "https://danielnoethen.de/butt/";
+    license = lib.licenses.gpl2;
+    maintainers = with lib.maintainers; [ ehmry ];
+    mainProgram = "butt";
+  };
+})