blob: a10b570f30bcd55316d1fb28f8d450714d5e7c5b (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
|
{ lib, config, pkgs, ... }:
let
cfg = config.services.ntpd-rs;
format = pkgs.formats.toml { };
configFile = format.generate "ntpd-rs.toml" cfg.settings;
in
{
options.services.ntpd-rs = {
enable = lib.mkEnableOption "Network Time Service (ntpd-rs)";
metrics.enable = lib.mkEnableOption "ntpd-rs Prometheus Metrics Exporter";
package = lib.mkPackageOption pkgs "ntpd-rs" { };
useNetworkingTimeServers = lib.mkOption {
type = lib.types.bool;
default = true;
description = lib.mdDoc ''
Use source time servers from {var}`networking.timeServers` in config.
'';
};
settings = lib.mkOption {
type = lib.types.submodule {
freeformType = format.type;
};
default = { };
description = lib.mdDoc ''
Settings to write to {file}`ntp.toml`
See <https://docs.ntpd-rs.pendulum-project.org/man/ntp.toml.5>
for more information about available options.
'';
};
};
config = lib.mkIf cfg.enable {
assertions = [
{
assertion = !config.services.timesyncd.enable;
message = ''
`ntpd-rs` is not compatible with `services.timesyncd`. Please disable one of them.
'';
}
];
environment.systemPackages = [ cfg.package ];
systemd.packages = [ cfg.package ];
services.timesyncd.enable = false;
systemd.services.systemd-timedated.environment = {
SYSTEMD_TIMEDATED_NTP_SERVICES = "ntpd-rs.service";
};
services.ntpd-rs.settings = {
observability = {
observation-path = lib.mkDefault "/var/run/ntpd-rs/observe";
};
source = lib.mkIf cfg.useNetworkingTimeServers (map
(ts: {
mode = "server";
address = ts;
})
config.networking.timeServers);
};
systemd.services.ntpd-rs = {
wantedBy = [ "multi-user.target" ];
serviceConfig = {
User = "";
Group = "";
DynamicUser = true;
ExecStart = [ "" "${lib.makeBinPath [ cfg.package ]}/ntp-daemon --config=${configFile}" ];
};
};
systemd.services.ntp-rs-metrics = lib.mkIf cfg.metrics.enable {
wantedBy = [ "multi-user.target" ];
serviceConfig = {
User = "";
Group = "";
DynamicUser = true;
ExecStart = [ "" "${lib.makeBinPath [ cfg.package ]}/bin/ntp-metrics-exporter --config=${configFile}" ];
};
};
};
meta.maintainers = with lib.maintainers; [ fpletz ];
}
|
