nixos/tests/nixos-test-driver/lib-extend.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31

{ pkgs, ... }:

let
  patchedPkgs = pkgs.extend (new: old: {
    lib = old.lib.extend (self: super: {
      sorry_dave = "sorry dave";
    });
  });

  testBody = {
    name = "demo lib overlay";

    nodes = {
      machine = { lib, ... }: {
        environment.etc."got-lib-overlay".text = lib.sorry_dave;
      };
    };

    # We don't need to run an actual test. Instead we build the `machine` configuration
    # and call it a day, because that already proves that `lib` is wired up correctly.
    # See the attrset returned at the bottom of this file.
    testScript = "";
  };

  inherit (patchedPkgs.testers) nixosTest runNixOSTest;
  evaluationNixosTest = nixosTest testBody;
  evaluationRunNixOSTest = runNixOSTest testBody;
in {
  nixosTest = evaluationNixosTest.driver.nodes.machine.system.build.toplevel;
  runNixOSTest = evaluationRunNixOSTest.driver.nodes.machine.system.build.toplevel;
}