pkgs/applications/backup/timeshift/wrapper.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45

{ stdenvNoCC
, lib
, wrapGAppsHook3
, gdk-pixbuf
, librsvg
, xorg
, shared-mime-info
}:

timeshift-unwrapped:
runtimeDeps:
stdenvNoCC.mkDerivation {
  inherit (timeshift-unwrapped) pname version;

  dontUnpack = true;

  nativeBuildInputs = [
    xorg.lndir
    wrapGAppsHook3
  ];

  installPhase = ''
    runHook preInstall
    mkdir -p "$out"
    lndir "${timeshift-unwrapped}" "$out"
    runHook postInstall
  '';

  dontWrapGApps = true;

  preFixup = ''
    makeWrapperArgs=(
      --prefix PATH : "${lib.makeBinPath runtimeDeps}"
    )
    gappsWrapperArgs+=(
      # Thumbnailers
      --prefix XDG_DATA_DIRS : "${lib.makeSearchPath "share" [ gdk-pixbuf librsvg shared-mime-info ]}"
      "''${makeWrapperArgs[@]}"
    )
    wrapProgram "$out/bin/timeshift" "''${makeWrapperArgs[@]}"
    wrapProgram "$out/bin/timeshift-gtk" "''${gappsWrapperArgs[@]}"
  '';

  inherit (timeshift-unwrapped) meta;
}