blob: b693aee613f74f553ca96df12781e66b90a6ff40 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
|
{ lib
, stdenvNoCC
, fetchzip
, copyDesktopItems
, jdk11
, makeDesktopItem
, makeWrapper
, unzip
, xdg-utils
}:
stdenvNoCC.mkDerivation rec {
pname = "irpf";
version = "2024-1.0";
# https://www.gov.br/receitafederal/pt-br/centrais-de-conteudo/download/pgd/dirpf
# Para outros sistemas operacionais -> Multi
src = let
year = lib.head (lib.splitVersion version);
in fetchzip {
url = "https://downloadirpf.receita.fazenda.gov.br/irpf/${year}/irpf/arquivos/IRPF${version}.zip";
hash = "sha256-x47Ud/aSfPuZYMZSGhJLnNFtNE62I+WjaFFatJPMPYg=";
};
nativeBuildInputs = [ unzip makeWrapper copyDesktopItems ];
desktopItems = [
(makeDesktopItem {
name = pname;
exec = pname;
icon = "rfb64";
desktopName = "Imposto de Renda Pessoa Física";
comment = "Programa Oficial da Receita para elaboração do IRPF";
categories = [ "Office" ];
})
];
installPhase = ''
runHook preInstall
BASEDIR="$out/share/${pname}"
mkdir -p "$BASEDIR"
cp --no-preserve=mode -r help lib lib-modulos "$BASEDIR"
install -Dm644 irpf.jar Leia-me.htm offline.png online.png pgd-updater.jar "$BASEDIR"
# make xdg-open overrideable at runtime
makeWrapper ${jdk11}/bin/java $out/bin/${pname} \
--add-flags "-Dawt.useSystemAAFontSettings=on" \
--add-flags "-Dswing.aatext=true" \
--add-flags "-jar $BASEDIR/${pname}.jar" \
--suffix PATH : ${lib.makeBinPath [ xdg-utils ]} \
--set _JAVA_AWT_WM_NONREPARENTING 1 \
--set AWT_TOOLKIT MToolkit
mkdir -p $out/share/pixmaps
unzip -j lib/ppgd-icones-4.0.jar icones/rfb64.png -d $out/share/pixmaps
runHook postInstall
'';
meta = with lib; {
description = "Brazillian government application for reporting income tax";
longDescription = ''
Brazillian government application for reporting income tax.
IRFP - Imposto de Renda Pessoa Física - Receita Federal do Brasil.
'';
homepage = "https://www.gov.br/receitafederal/pt-br";
license = licenses.unfree;
platforms = platforms.all;
sourceProvenance = with sourceTypes; [ binaryBytecode ];
maintainers = with maintainers; [ atila ];
mainProgram = "irpf";
};
}
|
