blob: 35c8dbf2f19aa9053ce60a04f073d733cf4c11d1 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
|
{ lib
, stdenv
, fetchurl
, glib
, jre
, unzip
, makeWrapper
, makeDesktopItem
, copyDesktopItems
, wrapGAppsHook
}:
let
icon = fetchurl {
url = "https://imagej.net/media/icons/imagej.png";
sha256 = "sha256-nU2nWI1wxZB/xlOKsZzdUjj+qiCTjO6GwEKYgZ5Risg=";
};
in stdenv.mkDerivation rec {
pname = "imagej";
version = "153";
src = fetchurl {
url = "https://wsr.imagej.net/distros/cross-platform/ij${version}.zip";
sha256 = "sha256-MGuUdUDuW3s/yGC68rHr6xxzmYScUjdXRawDpc1UQqw=";
};
nativeBuildInputs = [ copyDesktopItems makeWrapper unzip wrapGAppsHook ];
buildInputs = [ glib ];
dontWrapGApps = true;
desktopItems = lib.optionals stdenv.isLinux [
(makeDesktopItem {
name = "ImageJ";
desktopName = "ImageJ";
icon = "imagej";
categories = [ "Science" "Utility" "Graphics" ];
exec = "imagej";
})
];
passthru = {
inherit jre;
};
# JAR files that are intended to be used by other packages
# should go to $out/share/java.
# (Some uses ij.jar as a library not as a standalone program.)
installPhase = ''
runHook preInstall
mkdir -p $out/share/java $out/bin
# Read permisssion suffices for the jar and others.
# Simple cp shall clear suid bits, if any.
cp ij.jar $out/share/java
cp -dR luts macros plugins $out/share
runHook postInstall
'';
postFixup = lib.optionalString stdenv.isLinux ''
makeWrapper ${jre}/bin/java $out/bin/imagej \
''${gappsWrapperArgs[@]} \
--add-flags "-jar $out/share/java/ij.jar -ijpath $out/share"
install -Dm644 ${icon} $out/share/icons/hicolor/128x128/apps/imagej.png
substituteInPlace $out/share/applications/ImageJ.desktop \
--replace Exec=imagej Exec=$out/bin/imagej
'';
meta = with lib; {
homepage = "https://imagej.nih.gov/ij/";
description = "Image processing and analysis in Java";
longDescription = ''
ImageJ is a public domain Java image processing program
inspired by NIH Image for the Macintosh.
It runs on any computer with a Java 1.4 or later virtual machine.
'';
sourceProvenance = with sourceTypes; [ binaryBytecode ];
license = licenses.publicDomain;
platforms = platforms.unix;
maintainers = with maintainers; [ yuriaisaka ];
};
}
|