blob: 800ede30be4291b16d2aef30dd0f55e586ced48c (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
{ fetchFromGitHub
, installShellFiles
, lib
, pkg-config
, rustPlatform
, stdenv
, withSixel ? false
, libsixel
, xorg
, AppKit
, withSki ? true
}:
rustPlatform.buildRustPackage rec {
pname = "menyoki";
version = "1.7.0";
src = fetchFromGitHub {
owner = "orhun";
repo = pname;
rev = "v${version}";
sha256 = "sha256-owP3G1Rygraifdc4iPURQ1Es0msNhYZIlfrtj0CSU6Y=";
};
cargoSha256 = "sha256-NtXjlGkX8AzSw98xHPymzdnTipMIunyDbpSr4eVowa0=";
nativeBuildInputs = [ installShellFiles ]
++ lib.optional stdenv.isLinux pkg-config;
buildInputs = lib.optional withSixel libsixel
++ lib.optionals stdenv.isLinux (with xorg; [ libX11 libXrandr ])
++ lib.optional stdenv.isDarwin AppKit;
buildNoDefaultFeatures = !withSki;
buildFeatures = lib.optional withSixel "sixel";
checkFlags = [
# sometimes fails on lower end machines
"--skip=record::fps::tests::test_fps"
];
postInstall = ''
installManPage man/*
installShellCompletion completions/menyoki.{bash,fish,zsh}
'';
meta = with lib; {
description = "Screen{shot,cast} and perform ImageOps on the command line";
homepage = "https://menyoki.cli.rs/";
changelog = "https://github.com/orhun/menyoki/blob/v${version}/CHANGELOG.md";
license = licenses.gpl3Only;
maintainers = with maintainers; [ figsoda ];
mainProgram = "menyoki";
};
}
|
