1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
|
{ lib
, stdenv
, fetchFromGitHub
, alsa-lib
, appstream-glib
, clang
, cmake
, desktop-file-utils
, glib
, gstreamer
, gtk4
, libadwaita
, libxml2
, meson
, ninja
, pkg-config
, poppler
, python3
, rustPlatform
, shared-mime-info
, wrapGAppsHook4
}:
stdenv.mkDerivation rec {
pname = "rnote";
version = "0.5.9";
src = fetchFromGitHub {
owner = "flxzt";
repo = "rnote";
rev = "v${version}";
fetchSubmodules = true;
hash = "sha256-Sy8EHl4UuDMwRAKDkl7njD9GSzKpy1Cfsgw53On+nxo=";
};
cargoDeps = rustPlatform.fetchCargoTarball {
inherit src;
name = "${pname}-${version}";
hash = "sha256-Pe4lNcvJNELAitaGY56EUJ8iN7Dkh8DoUpA/t+aRuqk=";
};
nativeBuildInputs = [
appstream-glib # For appstream-util
clang
cmake
desktop-file-utils # For update-desktop-database
meson
ninja
pkg-config
python3 # For the postinstall script
rustPlatform.cargoSetupHook
rustPlatform.rust.cargo
rustPlatform.rust.rustc
shared-mime-info # For update-mime-database
wrapGAppsHook4
];
dontUseCmakeConfigure = true;
buildInputs = [
alsa-lib
glib
gstreamer
gtk4
libadwaita
libxml2
poppler
];
LIBCLANG_PATH = "${clang.cc.lib}/lib";
postPatch = ''
pushd build-aux
chmod +x meson_post_install.py
patchShebangs meson_post_install.py
substituteInPlace meson_post_install.py --replace "gtk-update-icon-cache" "gtk4-update-icon-cache"
popd
'';
meta = with lib; {
homepage = "https://github.com/flxzt/rnote";
changelog = "https://github.com/flxzt/rnote/releases/tag/${src.rev}";
description = "Simple drawing application to create handwritten notes";
license = licenses.gpl3Only;
maintainers = with maintainers; [ dotlambda yrd ];
platforms = platforms.linux;
};
}
|