1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
{ fetchFromGitHub, lib, stdenv
, git, gnupg, pass, pwgen, qrencode
, qtbase, qtsvg, qttools, qmake, wrapQtAppsHook
}:
stdenv.mkDerivation rec {
pname = "qtpass";
version = "1.4.0";
src = fetchFromGitHub {
owner = "IJHack";
repo = "QtPass";
rev = "v${version}";
sha256 = "sha256-oKLLmsuXD2Hb2LQ4tcJP2gpR6eLaM/JzDhRcRSpUPYI=";
};
postPatch = ''
substituteInPlace src/qtpass.cpp \
--replace "/usr/bin/qrencode" "${qrencode}/bin/qrencode"
'';
buildInputs = [ git gnupg pass qtbase qtsvg ];
nativeBuildInputs = [ qmake qttools wrapQtAppsHook ];
# HACK `propagatedSandboxProfile` does not appear to actually propagate the sandbox profile from `qt5.qtbase`
sandboxProfile = toString qtbase.__propagatedSandboxProfile;
qmakeFlags = [
# setup hook only sets QMAKE_LRELEASE, set QMAKE_LUPDATE too:
"QMAKE_LUPDATE=${qttools.dev}/bin/lupdate"
];
qtWrapperArgs = [
"--suffix PATH : ${lib.makeBinPath [ git gnupg pass pwgen ]}"
];
postInstall = ''
install -D qtpass.desktop -t $out/share/applications
install -D artwork/icon.svg $out/share/icons/hicolor/scalable/apps/qtpass-icon.svg
install -D qtpass.1 -t $out/share/man/man1
'';
meta = with lib; {
description = "A multi-platform GUI for pass, the standard unix password manager";
mainProgram = "qtpass";
homepage = "https://qtpass.org";
license = licenses.gpl3;
maintainers = [ maintainers.hrdinka ];
platforms = platforms.all;
};
}
|
