1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
|
{ stdenv
, fetchurl
, python27Packages
, gnome3
, gobject-introspection
, wrapGAppsHook
, webkitgtk
, libnotify
, keybinder3
, libappindicator
, intltool
, wmctrl
, hicolor-icon-theme
, xvfb_run
}:
python27Packages.buildPythonApplication rec {
pname = "ulauncher";
version = "4.4.0.r1";
# Python 3 support is currently in development
# on the dev branch and 5.x.x releases
disabled = ! python27Packages.isPy27;
src = fetchurl {
url = "https://github.com/Ulauncher/Ulauncher/releases/download/${version}/ulauncher_${version}.tar.gz";
sha256 = "12v7qpjhf0842ivsfflsl2zlvhiaw25f9ffv7vhnkvrhrmksim9f";
};
nativeBuildInputs = with python27Packages; [
distutils_extra
intltool
wrapGAppsHook
];
buildInputs = [
gnome3.adwaita-icon-theme
gobject-introspection
hicolor-icon-theme
keybinder3
libappindicator
libnotify
webkitgtk
wmctrl
];
propagatedBuildInputs = with python27Packages; [
dbus-python
notify
pygobject3
pyinotify
pysqlite
python-Levenshtein
pyxdg
websocket_client
];
checkInputs = with python27Packages; [
mock
pytest
pytest-mock
pytestpep8
xvfb_run
];
patches = [
./fix-path.patch
];
postPatch = ''
substituteInPlace setup.py --subst-var out
'';
# https://github.com/Ulauncher/Ulauncher/issues/390
doCheck = false;
preCheck = ''
export PYTHONPATH=$PYTHONPATH:$out/${python27Packages.python.sitePackages}
'';
# Simple translation of
# - https://github.com/Ulauncher/Ulauncher/blob/f5a601bdca75198a6a31b9d84433496b63530e74/test
checkPhase = ''
runHook preCheck
# skip tests in invocation that handle paths that
# aren't nix friendly (i think)
xvfb-run -s '-screen 0 1024x768x16' \
pytest -k 'not TestPath and not test_handle_key_press_event' --pep8 tests
runHook postCheck
'';
preFixup = ''
gappsWrapperArgs+=(--prefix PATH : "${stdenv.lib.makeBinPath [ wmctrl ]}")
'';
meta = with stdenv.lib; {
description = "A fast application launcher for Linux, written in Python, using GTK";
homepage = https://ulauncher.io/;
license = licenses.gpl3;
platforms = platforms.linux;
maintainers = with maintainers; [ aaronjanse worldofpeace ];
};
}
|
