blob: 34bf49304cb652e11b3b46817c759e0b0d5fc596 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
|
{ lib
, buildNpmPackage
, fetchFromGitHub
, makeDesktopItem
, copyDesktopItems
, makeWrapper
, electron
, python3
}:
let
version = "1.2.41";
electronSrc = fetchFromGitHub {
owner = "threema-ch";
repo = "threema-web-electron";
rev = "refs/tags/${version}";
hash = "sha256-gV64rNBwQxPpREi0NFzfCA7lSO65/h0CVRw2EcbFedM=";
};
threema-web = buildNpmPackage rec {
pname = "threema-web";
version = "2.5.3";
src = fetchFromGitHub {
owner = "threema-ch";
repo = "threema-web";
rev = "refs/tags/v${version}";
hash = "sha256-RIYyDoEck+a0kPUzTpdNLdyd4+ZYGjjkAlkCp9/S7FY=";
};
npmDepsHash = "sha256-OqiPpjIdLwBfxEmbI+YFmYGt3beMqXyGZc9FCwbng4U=";
npmBuildScript = "dist";
nativeBuildInputs = [
python3 # Used by gyp
];
patches = [
"${electronSrc}/tools/patches/patch-user-agent.patch"
"${electronSrc}/tools/patches/patch-looks.patch"
];
postInstall = ''
# Content of ${electronSrc}/tools/patches/post-patch-threema-web.sh
export threema_web_version=threema-web-${version}
sed -i.bak -E "s/IN_MEMORY_SESSION_PASSWORD:(true|false|0|1|\!0|\!1)/IN_MEMORY_SESSION_PASSWORD:true/g" -- release/$threema_web_version/*.bundle.js
cp -r . "$out"
'';
};
consumer = buildNpmPackage rec {
pname = "threema-desktop-consumer";
inherit version;
src = electronSrc;
sourceRoot = "${src.name}/app";
npmDepsHash = "sha256-AaUxnvrVCgKWCtMzeXexVBxs/NuVwWH67x4eBGAcsxk=";
env.ELECTRON_SKIP_BINARY_DOWNLOAD = "1";
dontNpmBuild = true;
prePatch = ''
rm -r dependencies/threema-web
cp -r ${threema-web} dependencies/threema-web
chmod +w dependencies/threema-web
'';
postInstall = ''
cp -r . "$out"
'';
};
in
buildNpmPackage rec {
pname = "threema-desktop";
inherit version;
src = electronSrc;
npmDepsHash = "sha256-f/Oy9cHBc9k54MDSeilPcTJe0txOS2sqNt2UCUf5+M8=";
env.ELECTRON_SKIP_BINARY_DOWNLOAD = "1";
postPatch = ''
rm -r app
cp -r ${consumer} app
chmod +w app
'';
npmBuildScript = "app:build:electron:main";
# We need to install the consumer
dontNpmInstall = true;
nativeBuildInputs = [
copyDesktopItems
makeWrapper
];
desktopItems = [
(makeDesktopItem {
name = "threema-desktop";
exec = meta.mainProgram;
icon = "threema";
desktopName = "Threema Desktop";
comment = meta.description;
})
];
postInstall = ''
mkdir -p $out/opt
cp -r app $out/opt/threema
for dir in assets dependencies; do
ln -s $out/opt/threema/$dir $out/opt/threema/dist/src/$dir
done
mkdir -p $out/share/pixmaps
cp $out/opt/threema/assets/icons/svg/consumer.svg $out/share/pixmaps/threema.svg
makeWrapper ${electron}/bin/electron $out/bin/threema \
--add-flags $out/opt/threema/dist/src/main.js
'';
meta = with lib; {
description = "Desktop client for Threema, a privacy-focused end-to-end encrypted mobile messenger";
homepage = "https://threema.ch";
license = licenses.agpl3Only;
mainProgram = "threema";
maintainers = with maintainers; [ wolfangaukang ];
platforms = [ "x86_64-linux" ];
};
}
|
