blob: 77b7e00b06186108accc42a3a17cae774dc6480c (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
|
{
stdenv,
config,
pkgs,
lib,
fetchFromGitHub,
cmake,
eigen,
onnxruntime,
opencv,
cudaSupport ? config.cudaSupport,
cudaPackages ? { },
}@inputs:
let
effectiveStdenv = if cudaSupport then cudaPackages.backendStdenv else inputs.stdenv;
in
effectiveStdenv.mkDerivation (finalAttrs: {
pname = "fastdeploy-ppocr";
version = "0-unstable-2023-10-09";
src = fetchFromGitHub {
owner = "MaaAssistantArknights";
repo = "FastDeploy";
# follows but not fully follows https://github.com/MaaAssistantArknights/MaaDeps/blob/master/vcpkg-overlay/ports/maa-fastdeploy/portfile.cmake#L4
rev = "0db6000aaac250824266ac37451f43ce272d80a3";
hash = "sha256-5TItnPDc5WShpZAgBYeqgI9KKkk3qw/M8HPMlq/H4BM=";
};
outputs = [
"out"
"cmake"
];
nativeBuildInputs = [
cmake
eigen
] ++ lib.optionals cudaSupport [ cudaPackages.cuda_nvcc ];
buildInputs =
[
onnxruntime
opencv
]
++ lib.optionals cudaSupport (
with cudaPackages;
[
cuda_cccl # cub/cub.cuh
libcublas # cublas_v2.h
libcurand # curand.h
libcusparse # cusparse.h
libcufft # cufft.h
cudnn # cudnn.h
cuda_cudart
]
);
cmakeFlags =
[
(lib.cmakeFeature "CMAKE_BUILD_TYPE" "None")
(lib.cmakeBool "BUILD_SHARED_LIBS" true)
]
++ lib.optionals cudaSupport [
(lib.cmakeFeature "CMAKE_CUDA_ARCHITECTURES" cudaPackages.flags.cmakeCudaArchitecturesString)
];
postInstall = ''
mkdir $cmake
install -Dm644 ${finalAttrs.src}/cmake/Findonnxruntime.cmake $cmake/
'';
meta = with lib; {
description = "MaaAssistantArknights stripped-down version of FastDeploy";
homepage = "https://github.com/MaaAssistantArknights/FastDeploy";
platforms = platforms.linux ++ platforms.darwin;
license = licenses.asl20;
broken = cudaSupport && stdenv.hostPlatform.system != "x86_64-linux";
};
})
|
