1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
|
{ buildGoModule
, cairo
, cargo
, cargo-tauri
, esbuild
, fetchFromGitHub
, gdk-pixbuf
, gobject-introspection
, lib
, libsoup
, llvmPackages_15
, makeBinaryWrapper
, nodejs
, pango
, pkg-config
, pnpm
, rustc
, rustPlatform
, stdenv
, stdenvNoCC
, wasm-bindgen-cli
, webkitgtk
}:
let
esbuild-18-20 = let version = "0.18.20";
in esbuild.override {
buildGoModule = args:
buildGoModule (args // {
inherit version;
src = fetchFromGitHub {
owner = "evanw";
repo = "esbuild";
rev = "v${version}";
hash = "sha256-mED3h+mY+4H465m02ewFK/BgA1i/PQ+ksUNxBlgpUoI=";
};
vendorHash = "sha256-+BfxCyg0KkDQpHt/wycy/8CTG6YBA/VJvJFhhzUnSiQ=";
});
};
wasm-bindgen-cli-2-92 = wasm-bindgen-cli.override {
version = "0.2.92";
hash = "sha256-1VwY8vQy7soKEgbki4LD+v259751kKxSxmo/gqE6yV0=";
cargoHash = "sha256-aACJ+lYNEU8FFBs158G1/JG8sc6Rq080PeKCMnwdpH0=";
};
in stdenv.mkDerivation (finalAttrs: {
pname = "surrealist";
version = "1.11.7";
src = fetchFromGitHub {
owner = "StarlaneStudios";
repo = "Surrealist";
rev = "v${finalAttrs.version}";
hash = "sha256-1jTvbr7jFo2GOB79ClwtBVVnNQlSEkqY2eqbiZxWG74=";
};
sourceRoot = "${finalAttrs.src.name}/src-tauri";
embed = stdenv.mkDerivation {
inherit (finalAttrs) src version;
pname = "${finalAttrs.pname}-embed";
sourceRoot = "${finalAttrs.src.name}/src-embed";
auditable = false;
dontInstall = true;
cargoDeps = rustPlatform.fetchCargoTarball {
inherit (finalAttrs) src;
sourceRoot = "${finalAttrs.src.name}/src-embed";
hash = "sha256-0cAhaeoP8EPcE1230CyznQZZIKRs0lrI8XOXECgb8pg=";
};
nativeBuildInputs = [
cargo
rustc
llvmPackages_15.clangNoLibc
llvmPackages_15.lld
rustPlatform.cargoSetupHook
wasm-bindgen-cli-2-92
];
postBuild = ''
CC=clang cargo build \
--target wasm32-unknown-unknown \
--release
wasm-bindgen \
target/wasm32-unknown-unknown/release/surrealist_embed.wasm \
--out-dir $out \
--out-name surrealist-embed \
--target web
'';
};
ui = stdenvNoCC.mkDerivation {
inherit (finalAttrs) src version;
pname = "${finalAttrs.pname}-ui";
dontFixup = true;
pnpmDeps = pnpm.fetchDeps {
inherit (finalAttrs) pname version src;
hash = "sha256-3x/GKgVX0mnxTZmINe/qTtr/vI0h5IqPYt9N0l/VGzg=";
};
ESBUILD_BINARY_PATH = "${lib.getExe esbuild-18-20}";
nativeBuildInputs = [ nodejs pnpm.configHook ];
postPatch = ''
ln -s ${finalAttrs.embed} src/generated
'';
postBuild = ''
pnpm build
'';
postInstall = ''
cp -r dist $out
'';
};
cargoDeps = rustPlatform.importCargoLock {
lockFile = ./Cargo.lock;
outputHashes = {
"tauri-plugin-localhost-0.1.0" =
"sha256-7PJgz6t/jPEwX/2xaOe0SYawfPSZw/F1QtOrc6iPiP0=";
};
};
nativeBuildInputs = [
cargo
cargo-tauri
makeBinaryWrapper
pkg-config
rustc
rustPlatform.cargoSetupHook
];
buildInputs =
[ cairo gdk-pixbuf gobject-introspection libsoup pango webkitgtk ];
postPatch = ''
substituteInPlace ./tauri.conf.json \
--replace '"distDir": "../dist",' '"distDir": "${finalAttrs.ui}",' \
--replace '"beforeBuildCommand": "pnpm build",' '"beforeBuildCommand": "",'
'';
postBuild = ''
cargo tauri build --bundles deb
'';
postInstall = ''
install -Dm555 target/release/bundle/deb/surrealist_${finalAttrs.version}_*/data/usr/bin/surrealist -t $out/bin
cp -r target/release/bundle/deb/surrealist_${finalAttrs.version}_*/data/usr/share $out
'';
postFixup = ''
wrapProgram "$out/bin/surrealist" --set WEBKIT_DISABLE_COMPOSITING_MODE 1
'';
meta = with lib; {
description = "Powerful graphical SurrealDB query playground and database explorer for Browser and Desktop";
homepage = "https://surrealist.starlane.studio";
license = licenses.mit;
mainProgram = "surrealist";
maintainers = with maintainers; [ frankp ];
platforms = platforms.linux;
# See comment about wasm32-unknown-unknown in rustc.nix.
broken = lib.any (a: lib.hasAttr a stdenv.hostPlatform.gcc) [ "cpu" "float-abi" "fpu" ] ||
!stdenv.hostPlatform.gcc.thumb or true;
};
})
|