blob: 9887f7f11c5226b29a4ea395ca46bf25e8b4ece7 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
|
{ lib
, stdenv
, fetchurl
, meson
, ninja
, gettext
, pkg-config
, glib
, gnome
, gnome-menus
, substituteAll
}:
stdenv.mkDerivation (finalAttrs: {
pname = "gnome-shell-extensions";
version = "46.2";
src = fetchurl {
url = "mirror://gnome/sources/gnome-shell-extensions/${lib.versions.major finalAttrs.version}/gnome-shell-extensions-${finalAttrs.version}.tar.xz";
hash = "sha256-1ELp0mklEl/yFaXBNCkElWVTgHQdqvuzejqZ1vDH2G8=";
};
patches = [
(substituteAll {
src = ./fix_gmenu.patch;
gmenu_path = "${gnome-menus}/lib/girepository-1.0";
})
];
nativeBuildInputs = [
meson
ninja
pkg-config
gettext
glib
];
mesonFlags = [
"-Dextension_set=all"
];
preFixup = ''
# Since we do not install the schemas to central location,
# let’s link them to where extensions installed
# through the extension portal would look for them.
# Adapted from export-zips.sh in the source.
extensiondir=$out/share/gnome-shell/extensions
schemadir=${glib.makeSchemaPath "$out" "$name"}
for f in $extensiondir/*; do
name=$(basename "''${f%%@*}")
schema=$schemadir/org.gnome.shell.extensions.$name.gschema.xml
schemas_compiled=$schemadir/gschemas.compiled
if [[ -f $schema ]]; then
mkdir "$f/schemas"
ln -s "$schema" "$f/schemas"
ln -s "$schemas_compiled" "$f/schemas"
fi
done
'';
passthru = {
updateScript = gnome.updateScript {
packageName = "gnome-shell-extensions";
attrPath = "gnome.gnome-shell-extensions";
};
};
meta = with lib; {
homepage = "https://gitlab.gnome.org/GNOME/gnome-shell-extensions";
description = "Modify and extend GNOME Shell functionality and behavior";
maintainers = teams.gnome.members;
license = licenses.gpl2Plus;
platforms = platforms.linux;
};
})
|