blob: b76482ba5963d00f3573f4cad755426a14f3734c (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
{ lib, stdenv, fetchFromGitHub, callPackage
, autoreconfHook, texinfo, libffi
}:
let
swig = callPackage ./swig.nix { };
bootForth = callPackage ./boot-forth.nix { };
lispDir = "${placeholder "out"}/share/emacs/site-lisp";
in stdenv.mkDerivation rec {
pname = "gforth";
version = "0.7.9_20230518";
src = fetchFromGitHub {
owner = "forthy42";
repo = "gforth";
rev = version;
hash = "sha256-rXtmmENBt9RMdLPq8GDyndh4+CYnCmz6NYpe3kH5OwU=";
};
nativeBuildInputs = [
autoreconfHook texinfo bootForth swig
];
buildInputs = [
libffi
];
passthru = { inherit bootForth; };
configureFlags = [
"--with-lispdir=${lispDir}"
] ++ lib.optionals (stdenv.isDarwin && stdenv.isx86_64) [
"--build=x86_64-apple-darwin"
];
preConfigure = ''
mkdir -p ${lispDir}
'';
meta = {
description = "The Forth implementation of the GNU project";
homepage = "https://github.com/forthy42/gforth";
license = lib.licenses.gpl3;
broken = stdenv.isDarwin && stdenv.isAarch64; # segfault when running ./gforthmi
platforms = lib.platforms.all;
};
}
|
