blob: 41462e67a4c980ee38eb845c8d9d155e26772458 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
{ lib
, stdenv
, fetchurl
, perl
, CoreServices
, ApplicationServices
}:
stdenv.mkDerivation rec {
pname = "moarvm";
version = "2022.02";
src = fetchurl {
url = "https://moarvm.org/releases/MoarVM-${version}.tar.gz";
sha256 = "sha256-T5PNzmuKVloyKCuzjMlxzv63H10CLIUMM47oFFV07pY=";
};
postPatch = ''
patchShebangs .
'' + lib.optionalString stdenv.isDarwin ''
substituteInPlace Configure.pl \
--replace '`/usr/bin/arch`' '"${stdenv.hostPlatform.darwinArch}"' \
--replace '/usr/bin/arch' "$(type -P true)" \
--replace '/usr/' '/nope/'
substituteInPlace 3rdparty/dyncall/configure \
--replace '`sw_vers -productVersion`' '"$MACOSX_DEPLOYMENT_TARGET"'
'';
buildInputs = [ perl ] ++ lib.optionals stdenv.isDarwin [ CoreServices ApplicationServices ];
doCheck = false; # MoarVM does not come with its own test suite
configureScript = "${perl}/bin/perl ./Configure.pl";
meta = with lib; {
description = "VM with adaptive optimization and JIT compilation, built for Rakudo";
homepage = "https://moarvm.org";
license = licenses.artistic2;
platforms = platforms.unix;
maintainers = with maintainers; [ thoughtpolice vrthra sgo ];
};
}
|