blob: 79296a8e04f6fa4729a1a9fa50d197d845bce3c5 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
{ lib
, stdenv
, fetchFromGitHub
, cmake
, coreutils
}:
stdenv.mkDerivation rec {
pname = "aws-c-common";
version = "0.6.18";
src = fetchFromGitHub {
owner = "awslabs";
repo = pname;
rev = "v${version}";
sha256 = "sha256-5Y+cfiVtZGmExPuE3s5m8hnd0HrPwSiKptj0DM1mtUY=";
};
nativeBuildInputs = [ cmake ];
cmakeFlags = [
"-DBUILD_SHARED_LIBS=ON"
"-DCMAKE_SKIP_BUILD_RPATH=OFF" # for tests
];
# aws-c-common misuses cmake modules, so we need
# to manually add a MODULE_PATH to its consumers
setupHook = ./setup-hook.sh;
# Prevent the execution of tests known to be flaky.
preCheck = let
ignoreTests = [
"promise_test_multiple_waiters"
] ++ lib.optionals stdenv.hostPlatform.isMusl [
"sba_metrics" # https://github.com/awslabs/aws-c-common/issues/839
];
in ''
cat <<EOW >CTestCustom.cmake
SET(CTEST_CUSTOM_TESTS_IGNORE ${toString ignoreTests})
EOW
'';
doCheck = true;
meta = with lib; {
description = "AWS SDK for C common core";
homepage = "https://github.com/awslabs/aws-c-common";
license = licenses.asl20;
platforms = platforms.unix;
maintainers = with maintainers; [ orivej eelco r-burns ];
};
}
|