blob: 7e44794620c030b459642bf994ff0c9c78847e9d (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
{ lib
, stdenv
, fetchFromGitHub
, cmake
, ninja
# Enable C++17 support
# https://github.com/google/googletest/issues/3081
# Projects that require a higher standard can override this package.
# For an example why that may be necessary, see:
# https://github.com/mhx/dwarfs/issues/188#issuecomment-1907574427
# Setting this to `null` does not pass any flags to set this.
, cxx_standard ? (
if (
(stdenv.cc.isGNU && (lib.versionOlder stdenv.cc.version "11.0"))
||
(stdenv.cc.isClang && (lib.versionOlder stdenv.cc.version "16.0"))
)
then "17"
else null
)
, static ? stdenv.hostPlatform.isStatic,
}:
stdenv.mkDerivation rec {
pname = "gtest";
version = "1.14.0";
outputs = [ "out" "dev" ];
src = fetchFromGitHub {
owner = "google";
repo = "googletest";
rev = "v${version}";
hash = "sha256-t0RchAHTJbuI5YW4uyBPykTvcjy90JW9AOPNjIhwh6U=";
};
patches = [
./fix-cmake-config-includedir.patch
];
nativeBuildInputs = [ cmake ninja ];
cmakeFlags = [
"-DBUILD_SHARED_LIBS=${if static then "OFF" else "ON"}"
] ++ lib.optionals (cxx_standard != null) [
"-DCMAKE_CXX_STANDARD=${cxx_standard}"
];
meta = with lib; {
description = "Google's framework for writing C++ tests";
homepage = "https://github.com/google/googletest";
license = licenses.bsd3;
platforms = platforms.all;
maintainers = with maintainers; [ ivan-tkatchev ];
};
}
|
