blob: 9c526b6fdce4e9e053cdd935e98e7bf6a3ff330b (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
{ lib
, stdenv
, fetchFromGitHub
, cmake
, boost
, eigen
, urdfdom
, pythonSupport ? false
, python3Packages
}:
stdenv.mkDerivation rec {
pname = "pinocchio";
version = "2.6.16";
src = fetchFromGitHub {
owner = "stack-of-tasks";
repo = pname;
rev = "v${version}";
fetchSubmodules = true;
hash = "sha256-ihyLoElqpIhsZXPF3o4XgbkzeE/BYdz8+WhLLcpc6PE=";
};
# error: use of undeclared identifier '__sincos'
postPatch = lib.optionalString (stdenv.isDarwin && stdenv.isx86_64) ''
substituteInPlace src/math/sincos.hpp \
--replace "__APPLE__" "0"
'';
strictDeps = true;
nativeBuildInputs = [
cmake
];
propagatedBuildInputs = [
urdfdom
] ++ lib.optionals (!pythonSupport) [
boost
eigen
] ++ lib.optionals pythonSupport [
python3Packages.boost
python3Packages.eigenpy
];
cmakeFlags = lib.optionals (!pythonSupport) [
"-DBUILD_PYTHON_INTERFACE=OFF"
];
meta = with lib; {
description = "A fast and flexible implementation of Rigid Body Dynamics algorithms and their analytical derivatives";
homepage = "https://github.com/stack-of-tasks/pinocchio";
license = licenses.bsd2;
maintainers = with maintainers; [ wegank ];
platforms = platforms.unix;
};
}
|