pkgs/development/python-modules/n3fit/default.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50

{ lib
, buildPythonPackage
, hyperopt
, keras
, nnpdf
, psutil
, tensorflow
, validphys2
}:

buildPythonPackage rec {
  pname = "n3fit";
  version = "4.0";
  format = "setuptools";

  inherit (nnpdf) src;

  prePatch = ''
    cd n3fit
  '';

  postPatch = ''
    substituteInPlace src/n3fit/version.py \
      --replace '= __give_git()' '= "'$version'"'
  '';

  propagatedBuildInputs = [
    hyperopt
    keras
    psutil
    tensorflow
    validphys2
  ];

  postInstall = ''
    for prog in "$out"/bin/*; do
      wrapProgram "$prog" --set PYTHONPATH "$PYTHONPATH:$(toPythonPath "$out")"
    done
  '';

  doCheck = false; # no tests
  pythonImportsCheck = [ "n3fit" ];

  meta = with lib; {
    description = "NNPDF fitting framework";
    homepage = "https://docs.nnpdf.science";
    inherit (nnpdf.meta) license;
    maintainers = with maintainers; [ veprbl ];
  };
}