blob: ea0453b8bc5974ed126556674f715b989ae32cc7 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
|
{
buildPythonPackage,
fetchFromGitHub,
lib,
libjpeg_turbo,
libpng,
ninja,
numpy,
pillow,
pytest,
scipy,
torch,
which,
}:
let
inherit (torch) cudaCapabilities cudaPackages cudaSupport;
inherit (cudaPackages) backendStdenv;
pname = "torchvision";
version = "0.18.1";
in
buildPythonPackage {
inherit pname version;
src = fetchFromGitHub {
owner = "pytorch";
repo = "vision";
rev = "refs/tags/v${version}";
hash = "sha256-aFm6CyoMA8HtpOAVF5Q35n3JRaOXYswWEqfooORUKsw=";
};
nativeBuildInputs = [
libpng
ninja
which
] ++ lib.optionals cudaSupport [ cudaPackages.cuda_nvcc ];
buildInputs = [
libjpeg_turbo
libpng
torch.cxxdev
];
dependencies = [
numpy
pillow
torch
scipy
];
preConfigure =
''
export TORCHVISION_INCLUDE="${libjpeg_turbo.dev}/include/"
export TORCHVISION_LIBRARY="${libjpeg_turbo}/lib/"
''
# NOTE: We essentially override the compilers provided by stdenv because we don't have a hook
# for cudaPackages to swap in compilers supported by NVCC.
+ lib.optionalString cudaSupport ''
export CC=${backendStdenv.cc}/bin/cc
export CXX=${backendStdenv.cc}/bin/c++
export TORCH_CUDA_ARCH_LIST="${lib.concatStringsSep ";" cudaCapabilities}"
export FORCE_CUDA=1
'';
# tries to download many datasets for tests
doCheck = false;
pythonImportsCheck = [ "torchvision" ];
checkPhase = ''
HOME=$TMPDIR py.test test --ignore=test/test_datasets_download.py
'';
nativeCheckInputs = [ pytest ];
meta = {
description = "PyTorch vision library";
homepage = "https://pytorch.org/";
license = lib.licenses.bsd3;
platforms = with lib.platforms; linux ++ lib.optionals (!cudaSupport) darwin;
maintainers = with lib.maintainers; [ ericsagnes ];
};
}
|