blob: 113633c5563134051ab4ff55c3151861f98137fa (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
|
{
lib,
stdenvNoCC,
buildPackages,
# macOS things
callPackage,
darwin-stubs,
}:
let
inherit (darwin-stubs) version;
fixup-frameworks = callPackage ./fixups.nix { };
private-frameworks = callPackage ./private.nix { };
public-frameworks = callPackage ./public.nix { };
mkDepsRewrites =
deps:
let
mergeRewrites = x: y: {
prefix = lib.mergeAttrs (x.prefix or { }) (y.prefix or { });
const = lib.mergeAttrs (x.const or { }) (y.const or { });
};
rewriteArgs =
{
prefix ? { },
const ? { },
}:
lib.concatLists (
(lib.mapAttrsToList (from: to: [
"-p"
"${from}:${to}"
]) prefix)
++ (lib.mapAttrsToList (from: to: [
"-c"
"${from}:${to}"
]) const)
);
rewrites =
depList:
lib.fold mergeRewrites { } (
map (dep: dep.tbdRewrites) (lib.filter (dep: dep ? tbdRewrites) depList)
);
in
lib.escapeShellArgs (rewriteArgs (rewrites (lib.attrValues deps)));
mkFramework =
{
name,
deps,
private ? false,
}:
let
standardFrameworkPath =
name: private:
"/System/Library/${lib.optionalString private "Private"}Frameworks/${name}.framework";
self = stdenvNoCC.mkDerivation {
pname = "apple-${lib.optionalString private "private-"}framework-${name}";
inherit (darwin-stubs) version;
# because we copy files from the system
preferLocalBuild = true;
dontUnpack = true;
dontBuild = true;
disallowedRequisites = [ darwin-stubs ];
nativeBuildInputs = [ buildPackages.darwin.rewrite-tbd ];
installPhase = ''
mkdir -p $out/Library/Frameworks
cp -r ${darwin-stubs}${standardFrameworkPath name private} $out/Library/Frameworks
if [[ -d ${darwin-stubs}/usr/lib/swift/${name}.swiftmodule ]]; then
mkdir -p $out/lib/swift
cp -r -t $out/lib/swift \
${darwin-stubs}/usr/lib/swift/${name}.swiftmodule \
${darwin-stubs}/usr/lib/swift/libswift${name}.tbd
fi
# Fix and check tbd re-export references
chmod u+w -R $out
find $out -name '*.tbd' -type f | while IFS=$'\n' read tbd; do
echo "Fixing re-exports in $tbd"
rewrite-tbd \
-p ${standardFrameworkPath name private}/:$out/Library/Frameworks/${name}.framework/ \
-p /usr/lib/swift/:$out/lib/swift/ \
${mkDepsRewrites deps} \
-r ${builtins.storeDir} \
"$tbd"
done
'';
propagatedBuildInputs = lib.attrValues deps;
passthru.tbdRewrites.prefix."${standardFrameworkPath name private}/" = "${self}/Library/Frameworks/${name}.framework/";
meta = with lib; {
description = "Apple SDK framework ${name}";
maintainers = with maintainers; [ ];
platforms = platforms.darwin;
};
};
in
self;
# Helper functions for creating framework derivations.
framework =
name: deps:
mkFramework {
inherit name deps;
private = false;
};
# Helper functions for creating private framework derivations.
privateFramework =
name: deps:
mkFramework {
inherit name deps;
private = true;
};
# Merge addToFrameworks into public-frameworks and remove elements of removeFromFrameworks.
deps =
let
inherit (fixup-frameworks) addToFrameworks removeFromFrameworks;
fixupDeps =
name: deps:
lib.pipe deps [
# Add dependencies from addToFrameworks.
(deps: lib.recursiveUpdate deps (addToFrameworks.${name} or { }))
# Keep dependencies not in removeFromFrameworks.
(lib.filterAttrs (depName: _: !(removeFromFrameworks.${name}.${depName} or false)))
];
in
lib.mapAttrs fixupDeps public-frameworks;
# Create derivations and add private frameworks.
bareFrameworks =
(lib.mapAttrs framework deps) // (lib.mapAttrs privateFramework private-frameworks);
in
bareFrameworks // fixup-frameworks.overrideFrameworks bareFrameworks
|