blob: bd8873ce100e77cec355c4887c4d16f1c7976dcb (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
|
{ buildGoModule
, fetchFromGitHub
, lib
, envoy
, mkYarnPackage
, fetchYarnDeps
, nixosTests
, pomerium-cli
}:
let
inherit (lib) concatStringsSep concatMap id mapAttrsToList;
in
buildGoModule rec {
pname = "pomerium";
version = "0.26.0";
src = fetchFromGitHub {
owner = "pomerium";
repo = "pomerium";
rev = "v${version}";
hash = "sha256-AkpfLKPirl8fz4s0hQI15aSgI2PZFPakAzC+j66MVY0=";
};
vendorHash = "sha256-kabWL7yqNkI2JRPmVv0tp0nIfVDwT9QbbDIbdM8sL5s=";
ui = mkYarnPackage {
inherit version;
src = "${src}/ui";
packageJSON = ./package.json;
offlineCache = fetchYarnDeps {
yarnLock = "${src}/ui/yarn.lock";
sha256 = lib.fileContents ./yarn-hash;
};
buildPhase = ''
runHook preBuild
yarn --offline build
runHook postBuild
'';
installPhase = ''
runHook preInstall
cp -R deps/pomerium/dist $out
runHook postInstall
'';
doDist = false;
};
subPackages = [
"cmd/pomerium"
];
# patch pomerium to allow use of external envoy
patches = [
./0001-envoy-allow-specification-of-external-binary.patch
];
ldflags = let
# Set a variety of useful meta variables for stamping the build with.
setVars = {
"github.com/pomerium/pomerium/internal/version" = {
Version = "v${version}";
BuildMeta = "nixpkgs";
ProjectName = "pomerium";
ProjectURL = "github.com/pomerium/pomerium";
};
"github.com/pomerium/pomerium/pkg/envoy" = {
OverrideEnvoyPath = "${envoy}/bin/envoy";
};
};
concatStringsSpace = list: concatStringsSep " " list;
mapAttrsToFlatList = fn: list: concatMap id (mapAttrsToList fn list);
varFlags = concatStringsSpace (
mapAttrsToFlatList (package: packageVars:
mapAttrsToList (variable: value:
"-X ${package}.${variable}=${value}"
) packageVars
) setVars);
in [
"${varFlags}"
];
preBuild = ''
# Replace embedded envoy with nothing.
# We set OverrideEnvoyPath above, so rawBinary should never get looked at
# but we still need to set a checksum/version.
rm pkg/envoy/files/files_{darwin,linux}*.go
cat <<EOF >pkg/envoy/files/files_external.go
package files
import _ "embed" // embed
var rawBinary []byte
//go:embed envoy.sha256
var rawChecksum string
//go:embed envoy.version
var rawVersion string
EOF
sha256sum '${envoy}/bin/envoy' > pkg/envoy/files/envoy.sha256
echo '${envoy.version}' > pkg/envoy/files/envoy.version
# put the built UI files where they will be picked up as part of binary build
cp -r ${ui}/* ui/dist
'';
installPhase = ''
install -Dm0755 $GOPATH/bin/pomerium $out/bin/pomerium
'';
passthru = {
tests = {
inherit (nixosTests) pomerium;
inherit pomerium-cli;
};
updateScript = ./updater.sh;
};
meta = with lib; {
homepage = "https://pomerium.io";
description = "Authenticating reverse proxy";
mainProgram = "pomerium";
license = licenses.asl20;
maintainers = with maintainers; [ lukegb devusb ];
platforms = [ "x86_64-linux" "aarch64-linux" ];
};
}
|