blob: 89b9bc2dd3dbb630f2c9f3944d6e454dbbb5adda (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
{ lib, python3Packages, fetchFromGitHub, wrapGAppsHook, gobject-introspection, libpulseaudio, glib, gtk3, pango, xorg }:
python3Packages.buildPythonApplication rec {
pname = "volctl";
version = "0.9.4";
src = fetchFromGitHub {
owner = "buzz";
repo = pname;
rev = "v${version}";
sha256 = "sha256-jzS97KV17wKeBI6deKE4rEj5lvqC38fq1JGundHn2So=";
};
postPatch = ''
substituteInPlace volctl/xwrappers.py \
--replace 'libXfixes.so' "${xorg.libXfixes}/lib/libXfixes.so" \
--replace 'libXfixes.so.3' "${xorg.libXfixes}/lib/libXfixes.so.3"
'';
preBuild = ''
export LD_LIBRARY_PATH=${libpulseaudio}/lib
'';
nativeBuildInputs = [
gobject-introspection
wrapGAppsHook
];
propagatedBuildInputs = [ pango gtk3 ] ++ (with python3Packages; [
pulsectl
click
pycairo
pygobject3
pyyaml
]);
# with strictDeps importing "gi.repository.Gtk" fails with "gi.RepositoryError: Typelib file for namespace 'Pango', version '1.0' not found"
strictDeps = false;
# no tests included
doCheck = false;
pythonImportsCheck = [ "volctl" ];
preFixup = ''
glib-compile-schemas ${glib.makeSchemaPath "$out" "${pname}-${version}"}
gappsWrapperArgs+=(--prefix LD_LIBRARY_PATH : "${libpulseaudio}/lib")
'';
meta = with lib; {
description = "PulseAudio enabled volume control featuring per-app sliders";
homepage = "https://buzz.github.io/volctl/";
license = licenses.gpl2Only;
platforms = platforms.linux;
maintainers = [ maintainers.romildo ];
mainProgram = "volctl";
};
}
|
