pkgs/tools/compression/pigz/default.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41

{ lib, stdenv, fetchFromGitHub, zlib, util-linux }:

stdenv.mkDerivation rec {
  pname = "pigz";
  version = "2.8";

  src = fetchFromGitHub {
      owner = "madler";
      repo = pname;
      rev = "refs/tags/v${version}";
      sha256 = "sha256-PzdxyO4mCg2jE/oBk1MH+NUdWM95wIIIbncBg71BkmQ=";
  };

  enableParallelBuilding = true;

  buildInputs = [ zlib ] ++ lib.optional stdenv.isLinux util-linux;

  makeFlags = [ "CC=${stdenv.cc}/bin/${stdenv.cc.targetPrefix}cc" ];

  doCheck = stdenv.isLinux;
  checkTarget = "tests";
  installPhase = ''
    runHook preInstall

    install -Dm755 pigz "$out/bin/pigz"
    ln -s pigz "$out/bin/unpigz"
    install -Dm755 pigz.1 "$out/share/man/man1/pigz.1"
    ln -s pigz.1 "$out/share/man/man1/unpigz.1"
    install -Dm755 pigz.pdf "$out/share/doc/pigz/pigz.pdf"

    runHook postInstall
  '';

  meta = with lib; {
    homepage = "https://www.zlib.net/pigz/";
    description = "A parallel implementation of gzip for multi-core machines";
    maintainers = with maintainers; [ ];
    license = licenses.zlib;
    platforms = platforms.unix;
  };
}