blob: 45e9a08a356fb98d665baa4824e4d8bcd8398ea2 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
{ lib, buildGoModule, fetchFromGitHub, openssl, pkg-config, libpcap }:
buildGoModule rec {
pname = "mongo-tools";
version = "100.5.3";
src = fetchFromGitHub {
owner = "mongodb";
repo = "mongo-tools";
rev = version;
sha256 = "sha256-8RkpBCFVxKVsu4h2z+rhlwvYfbSDHZUg8erO4+2GRbw=";
};
vendorSha256 = null;
nativeBuildInputs = [ pkg-config ];
buildInputs = [ openssl libpcap ];
# Mongodb incorrectly names all of their binaries main
# Let's work around this with our own installer
buildPhase =
let
tools = [
"bsondump"
"mongodump"
"mongoexport"
"mongofiles"
"mongoimport"
"mongorestore"
"mongostat"
"mongotop"
]; in
''
# move vendored codes so nixpkgs go builder could find it
runHook preBuild
${lib.concatMapStrings (t: ''
go build -o "$out/bin/${t}" -tags ssl -ldflags "-s -w" ./${t}/main
'') tools}
runHook postBuild
'';
meta = {
homepage = "https://github.com/mongodb/mongo-tools";
description = "Tools for the MongoDB";
license = lib.licenses.asl20;
maintainers = with lib.maintainers; [ bryanasdev000 ];
};
}
|