blob: 669fa6a494134c8d3df1e2625e7e6c19396e2b3b (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
|
{ lib
, stdenvNoCC
, fetchFromGitHub
, fetchpatch
, cowsay
, coreutils
, findutils
}:
stdenvNoCC.mkDerivation rec {
pname = "pokemonsay";
version = "1.0.0";
src = fetchFromGitHub {
owner = "HRKings";
repo = "pokemonsay-newgenerations";
rev = "v${version}";
hash = "sha256-IDTAZmOzkUg0kLUM0oWuVbi8EwE4sEpLWrNAtq/he+g=";
};
patches = [
(fetchpatch { # https://github.com/HRKings/pokemonsay-newgenerations/pull/5
name = "word-wrap-fix.patch";
url = "https://github.com/pbsds/pokemonsay-newgenerations/commit/7056d7ba689479a8e6c14ec000be1dfcd83afeb0.patch";
hash = "sha256-aqUJkyJDWArLjChxLZ4BbC6XAB53LAqARzTvEAxrFCI=";
})
];
postPatch = ''
substituteInPlace pokemonsay.sh \
--replace-fail \
'INSTALL_PATH=''${HOME}/.bin/pokemonsay' \
"" \
--replace-fail \
'POKEMON_PATH=''${INSTALL_PATH}/pokemons' \
'POKEMON_PATH=${placeholder "out"}/share/pokemonsay' \
--replace-fail \
'$(find ' \
'$(${findutils}/bin/find ' \
--replace-fail \
'$(basename ' \
'$(${coreutils}/bin/basename ' \
--replace-fail \
'cowsay -f ' \
'${cowsay}/bin/cowsay -f ' \
--replace-fail \
'cowthink -f ' \
'${cowsay}/bin/cowthink -f '
substituteInPlace pokemonthink.sh \
--replace-fail \
'./pokemonsay.sh' \
"${placeholder "out"}/bin/pokemonsay"
'';
installPhase = ''
mkdir -p $out/{bin,share/pokemonsay}
cp pokemonsay.sh $out/bin/pokemonsay
cp pokemonthink.sh $out/bin/pokemonthink
cp pokemons/*.cow $out/share/pokemonsay
'';
doInstallCheck = true;
installCheckPhase = ''
(set -x
test "$($out/bin/pokemonsay --list | wc -l)" -ge 891
)
'';
meta = with lib; {
description = "Print pokemon in the CLI! An adaptation of the classic cowsay";
homepage = "https://github.com/HRKings/pokemonsay-newgenerations";
license = licenses.mit;
platforms = platforms.all;
maintainers = with maintainers; [ pbsds ];
};
}
|
