blob: 8bdcd8708d9fbcc9c551c4a88d6c54c6dccdb737 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
{ lib
, stdenv
, fetchzip
, nixosTests
, iptables
, iproute2
, makeWrapper
, openresolv
, procps
, wireguard-go
}:
stdenv.mkDerivation rec {
pname = "wireguard-tools";
version = "1.0.20210315";
src = fetchzip {
url = "https://git.zx2c4.com/wireguard-tools/snapshot/wireguard-tools-${version}.tar.xz";
sha256 = "sha256-aCqgjriqhBInK7C7KapoKVfgj+zreGQzacMKwbMF1Og=";
};
outputs = [ "out" "man" ];
sourceRoot = "source/src";
nativeBuildInputs = [ makeWrapper ];
makeFlags = [
"DESTDIR=$(out)"
"PREFIX=/"
"WITH_BASHCOMPLETION=yes"
"WITH_SYSTEMDUNITS=yes"
"WITH_WGQUICK=yes"
];
postFixup = ''
substituteInPlace $out/lib/systemd/system/wg-quick@.service \
--replace /usr/bin $out/bin
'' + lib.optionalString stdenv.isLinux ''
for f in $out/bin/*; do
wrapProgram $f --prefix PATH : ${lib.makeBinPath [ procps iproute2 iptables openresolv ]}
done
'' + lib.optionalString stdenv.isDarwin ''
for f in $out/bin/*; do
wrapProgram $f --prefix PATH : ${wireguard-go}/bin
done
'';
passthru = {
updateScript = ./update.sh;
tests = nixosTests.wireguard;
};
meta = with lib; {
description = "Tools for the WireGuard secure network tunnel";
downloadPage = "https://git.zx2c4.com/wireguard-tools/refs/";
homepage = "https://www.wireguard.com/";
license = licenses.gpl2;
maintainers = with maintainers; [ elseym ericsagnes mic92 zx2c4 globin ma27 xwvvvvwx ];
platforms = platforms.unix;
};
}
|
