blob: c08c20daadcf46f6d18287730bb28390cd2b3acc (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
|
{ config, pkgs, lib, ... }:
let
cfg = config.vuizvui.hardware.t100ha;
desc = "hardware support for the ASUS T100HA convertible";
in {
options.vuizvui.hardware.t100ha.enable = lib.mkEnableOption desc;
config = lib.mkIf cfg.enable {
# It's a CherryTrail SoC, so we want to have the latest and greatest with a
# few additional patches:
boot.kernelPackages = let
argsOverride = {
kernelPatches = [
{ name = "backlight";
patch = ./backlight.patch;
}
{ name = "meta-keys";
patch = ./meta-keys.patch;
}
];
extraConfig = ''
MMC y
MMC_BLOCK y
MMC_SDHCI y
MMC_SDHCI_ACPI y
PINCTRL_CHERRYVIEW y
INTEL_SOC_PMIC y
AGP n
DRM y
DRM_I915 y
'';
};
patched = pkgs.linux_testing.override { inherit argsOverride; };
self = pkgs.linuxPackagesFor patched self;
in self;
# By default the console is rotated by 90 degrees to the right.
boot.kernelParams = [ "fbcon=rotate:3" ];
services.xserver.deviceSection = ''
Option "monitor-DSI1" "Monitor[0]"
'';
services.xserver.monitorSection = ''
Option "Rotate" "left"
'';
services.xserver.videoDriver = "intel";
# The touch screen needs to be rotated as well:
services.xserver.inputClassSections = lib.singleton ''
Identifier "touchscreen"
MatchProduct "SIS0457"
Option "TransformationMatrix" "0 -1 1 1 0 0 0 0 1"
'';
# XXX: Workaround for a vblank issue that causes the display to stay blank
# until the next subsequent vblank (usually on no activity for a while until
# the monitor gets powered down).
#
# I know this is very ugly, but another mitigation would be to disable power
# management entirely, which I think is even uglier.
services.xserver.displayManager.sessionCommands = ''
${pkgs.xorg.xset}/bin/xset dpms force standby
${pkgs.xorg.xset}/bin/xset dpms force on
'';
};
}
|
